How to move several worksheets in one workbook to several different workbooks

Hello everyone. I have worksheet, named "105", that contains several worksheets. I would like to move those worksheets to several other workbooks, with various names. Please see the code below:

Sub Disclosure_Generation()
    Const sFileInp1 As String = "105.xlsm"
    Const sFileInp2 As String = "Borrowing_Portfolio_Bonds.xlsm"
    Const sFileInp3 As String = "Borrowing_Portfolio_Swaps.xlsm"
    Const sFileInp4 As String = "Client_Operations.xlsm"
    Const sFileInp5 As String = "Other_Equity.xlsm"
    Dim sPath1      As String
    Dim sPath2      As String
    Dim wb1         As Workbook
    Dim wb2         As Workbook
    Dim wb3         As Workbook
    Dim wb4         As Workbook
    Dim wb5         As Workbook
      
    sPath1 = fPath & fDate & "_157\105_Reports\"
    sPath2 = fPath & fDate & "_157\157_Reports\IBRD_Disclosure\"
    
    Set wb2 = Workbooks.Open(sPath2 & sFileInp2)
    Set wb3 = Workbooks.Open(sPath2 & sFileInp3)
    Set wb4 = Workbooks.Open(sPath2 & sFileInp4)
    Set wb5 = Workbooks.Open(sPath2 & sFileInp5)
    Set wb1 = Workbooks.Open(sPath1 & sFileInp1)
    
    Sheets("Bonds").Move Before:=Workbooks("Borrowing_Portfolio_Bonds.xlsm"). _
        Sheets(1)
    Sheets("Bond_Details").Move Before:=Workbooks( _
        "Borrowing_Portfolio_Bonds.xlsm").Sheets(1) <---------- Error
        
    Sheets("Swaps").Move Before:=Workbooks("Borrowing_Portfolio_Swaps.xlsm"). _
        Sheets(1)
    Sheets("Swap_Details").Move Before:=Workbooks( _
        "Borrowing_Portfolio_Swaps.xlsm").Sheets(1)
    
    Sheets("Client_Operations").Move Before:=Workbooks("Client_Operations.xlsm"). _
        Sheets(1)
    Sheets("Client_Operations_Details").Move Before:=Workbooks( _
        "Client_Operations.xlsm").Sheets(1)
        
    Sheets("Other_Equity").Move Before:=Workbooks("Other_Equity.xlsm"). _
        Sheets(1)
    Sheets("Client_Operations_Details").Move Before:=Workbooks( _
        "Other_Equity.xlsm").Sheets(1)
        
    wb1.Close SaveChanges:=True
    wb2.Close SaveChanges:=True
    wb3.Close SaveChanges:=True
    wb4.Close SaveChanges:=True
    wb5.Close SaveChanges:=True

End Sub

I am getting an error, "subscript out of range", and I not sure of a correct fix. Any suggestions. Thank you.

This error is occuring because once you move a sheet to a different workbook, that workbook becomes the active workbook. Before you can move another sheet in your source workbook, you need to activate it. Does that make sense?

I don't see the name of your source workbook, but before the line with the error you should put:

Workbooks("Source Workbook Name").Activate

You'll need to put that after each line of code that moves a sheet to a different workbook.

Subscript out of Range usually indicates you are refering to an object incorrectly. I'd check the spelling on each item in parantheses above.

You should utilize all the variables you've declared throughout the entire macro to keep the code easy to to edit...you need only edit your strings at the top.

For moving sheets, be sure to include the parent object wb1 as the source for the sheets you're trying to move.

This is how I would adjust your macro:

Option Explicit
Const sFileInp1 As String = "105.xlsm"
Const sFileInp2 As String = "Borrowing_Portfolio_Bonds.xlsm"
Const sFileInp3 As String = "Borrowing_Portfolio_Swaps.xlsm"
Const sFileInp4 As String = "Client_Operations.xlsm"
Const sFileInp5 As String = "Other_Equity.xlsm"

Sub Disclosure_Generation()
Dim sPath1      As String
Dim sPath2      As String
Dim wb1         As Workbook
Dim wb2         As Workbook
Dim wb3         As Workbook
Dim wb4         As Workbook
Dim wb5         As Workbook
Application.ScreenUpdating = False

sPath1 = fPath & fDate & "_157\105_Reports\"
sPath2 = fPath & fDate & "_157\157_Reports\IBRD_Disclosure\"

Set wb2 = Workbooks.Open(sPath2 & sFileInp2)
Set wb3 = Workbooks.Open(sPath2 & sFileInp3)
Set wb4 = Workbooks.Open(sPath2 & sFileInp4)
Set wb5 = Workbooks.Open(sPath2 & sFileInp5)
Set wb1 = Workbooks.Open(sPath1 & sFileInp1)
    
    wb1.Sheets("Bonds").Move _
        Before:=Workbooks(sFileInp2).Sheets(1)
    wb1.Sheets("Bond_Details").Move _
        Before:=Workbooks(sFileInp2).Sheets(1)
    wb1.Sheets("Swaps").Move _
        Before:=Workbooks(sFileInp3).Sheets(1)
    wb1.Sheets("Swap_Details").Move _
        Before:=Workbooks(sFileInp3).Sheets(1)
    wb1.Sheets("Client_Operations").Move _
        Before:=Workbooks(sFileInp4).Sheets(1)
    wb1.Sheets("Client_Operations_Details").Move _
        Before:=Workbooks(sFileInp4).Sheets(1)
    wb1.Sheets("Other_Equity").Move _
        Before:=Workbooks(sFileInp5).Sheets(1)
    wb1.Sheets("Client_Operations_Details").Move _
        Before:=Workbooks(sFileInp5).Sheets(1)
            
    wb1.Close SaveChanges:=True
    wb2.Close SaveChanges:=True
    wb3.Close SaveChanges:=True
    wb4.Close SaveChanges:=True
    wb5.Close SaveChanges:=True

Application.ScreenUpdating = True
End Sub