Bring Excel to foreground from VBA

Your post does not comply with Rule 3 of our Forum RULES. Use code tags around code. Posting code without them makes your code hard to read and difficult to be copied for testing. Highlight your code and click the # at the top of your post window. For more information about these and other tags, found here

From a post by Jim Rech.

Public Declare Function GetWindowThreadProcessId Lib _
 "user32" (ByVal hWnd As Long, lpdwProcessId As Long) As Long
Public Declare Function AttachThreadInput Lib "user32" _
(ByVal idAttach As Long, ByVal idAttachTo As Long, _
 ByVal fAttach As Long) As Long
Public Declare Function GetForegroundWindow Lib "user32" () As Long
Public Declare Function SetForegroundWindow Lib "user32" _
 (ByVal hWnd As Long) As Long
Public Declare Function IsIconic Lib "user32" _
  (ByVal hWnd As Long) As Long
Public Declare Function ShowWindow Lib "user32" _
 (ByVal hWnd As Long, ByVal nCmdShow As Long) As Long
Declare Function FindWindowA Lib "user32" (ByVal lpClassName _
  As Long, ByVal lpWindowName As String) As Long

Const SW_SHOW = 5
Const SW_RESTORE = 9

''Run this an then switch to another application.
Sub Test2()
Application.OnTime Now + TimeValue("00:00:05"), "BringTotop"
End Sub

Sub BringToTop()
ForceForegroundWindow FindWindowA(0, Application.Caption)
End Sub

''All this is necessary in Windows 98/NT5 because MS disabled
'' SetForegroundWindow unless
'' the caller is itself the foreground window.
''  From Visual Basic Programmers Journal Feb 1999 pg 94
Function ForceForegroundWindow(ByVal hWnd As Long) As Boolean
    Dim ThreadID1 As Long
    Dim ThreadID2 As Long
    Dim nRet As Long

Debug.Print hWnd

    If hWnd = GetForegroundWindow Then
        ForceForegroundWindow = True
    Else
        ThreadID1 = GetWindowThreadProcessId( _
          GetForegroundWindow, ByVal 0&)
        ThreadID2 = GetWindowThreadProcessId(hWnd, ByVal 0&)
        If ThreadID1 <> ThreadID2 Then
            AttachThreadInput ThreadID1, ThreadID2, True
            nRet = SetForegroundWindow(hWnd)
            AttachThreadInput ThreadID1, ThreadID2, False
        Else
            nRet = SetForegroundWindow(hWnd)
        End If
        If IsIconic(hWnd) Then
            ShowWindow hWnd, SW_RESTORE
        Else
            ShowWindow hWnd, SW_SHOW
        End If
        ForceForegroundWindow = CBool(nRet)
    End If
End Function

No need to quote my post. It just waste space.

The code works for me.
What happens for you. Code runs but does not bring window to foreground.
Or does it error?
What if you put a breakpoint in the code does it even run?

this workbook works for me.