If Worksheet like (*Comments*) exists do the following. Use of wildcards in Function

Hi All.

I have a very useful function that I have found online:

Function wsExists(wksName As String) As Boolean
    On Error Resume Next
    wsExists = CBool(Len(Worksheets(wksName).Name) > 0)
    On Error GoTo 0
End Function

'Example
Sub testUDF()
    If wsExists("Comments") Then
        MsgBox "It exists"
Else: MsgBox "Not there"
    End If
End Sub

The above function works great - What it doesn't do is allow the use of a wildcard in the sheet name to search for.

What I would like is a modification to the above function or code to allow me to use a wildcard to search for sheets

...Like (*Comments*) then ...

Any help appreciated as always.
Cheers,
Mark

This is one way with a different approach:

Function wsPartExist(wksName As String) As Boolean

Dim wsEachSheet

For Each wsEachSheet In Worksheets

    If InStr(UCase(wsEachSheet.Name), UCase(wksName)) > 0 Then wsPartExist = True

Next wsEachSheet

End Function

Dom

You could use something like:

Function wsExists(ByVal wksName As String, Optional blnPartial As Boolean = False) As Boolean
    Dim wks As Worksheet
    If blnPartial Then
        For Each wks In ActiveWorkbook.Worksheets
            If InStr(1, wks.Name, wksName, vbTextCompare) > 0 Then
                wsExists = True
                Exit Function
            End If
        Next wks
    Else
        On Error Resume Next
        wsExists = CBool(Len(Worksheets(wksName).Name) > 0)
    End If
End Function

called as either:

    If wsExists("Comments") Then

for exact match or:

    If wsExists("Comments", true) Then

for partial match.

If you want specific combinations of wildcards, then you could use Like instead.

Application.DisplayAlerts = False
ActiveWorkbook.Close True
Application.DisplayAlerts = True

Dom

Untested, but something like:

Function wsExists(ByVal wksName As String, Optional blnPartial As Boolean = False, Optional blnMatchCase As Boolean = False) As Boolean
    Dim wks As Worksheet
    If blnPartial Then
        wksName = Replace(wksName, "*", "%")
        If blnMatchCase Then
            For Each wks In ActiveWorkbook.Worksheets
                If wks.Name Like wksName Then
                    wsExists = True
                    Exit Function
                End If
            Next wks
        Else
            wksName = UCase$(wksName)
            For Each wks In ActiveWorkbook.Worksheets
                If UCase$(wks.Name) Like wksName Then
                    wsExists = True
                    Exit Function
                End If
            Next wks
        End If
    Else
        If blnMatchCase Then
            For Each wks In ActiveWorkbook.Worksheets
                If StrComp(wks.Name, wksName, vbBinaryCompare) = 0 Then
                    wsExists = True
                    Exit Function
                End If
            Next wks
        Else
            On Error Resume Next
            wsExists = CBool(Len(Worksheets(wksName).Name) > 0)
        End If
    End If
End Function