Streaming Data behind a Java Script

Or, with minimum writing into the worksheet:

Sub snb()
  With New InternetExplorer
    .Navigate "http://www.cmegroup.com/trading/agricultural/grain-and-oilseed/corn_quotes_openOutcry.html"
        
    Do While .ReadyState <> 4
      DoEvents
    Loop
        
    With .Document
      sq = Cells(1, 1).Resize(.all.tags("table")(21).Rows.Length - 1, .all.tags("table")(21).Rows(1).Cells.Length)
          
      Do
        DoEvents
      Loop While InStr(.all.tags("table")(21).innertext, "'") = 0

      For j = 1 To UBound(sq)
        For jj = 1 To UBound(sq, 2)
          sq(j, jj) = Replace(.all.tags("table")(21).Rows(j - 1).Cells(jj - 1).innertext, vbCr, "")
        Next
      Next
    End With
  End With

  Sheets(1).Cells(1, 1).Resize(UBound(sq), UBound(sq, 2)) = sq
End Sub

Hi snb,

Thanks for the help/code, I'm a little busy right now so I wasn't able to check your code to see if it works, but I appreciate the help anyways. Thanks.

Hi Antoka05,

Thanks for the help! Much appreciated. I'm testing it across the markets I'm using (modifying for sheet name and url). However for some reason it did not work for this link:

http://www.cmegroup.com/trading/inte...sury-bond.html

I get the following error:

An Error Occurred: 91 - Object Variable or With Block Variable not set

Is there a way around this?

Sub ReadZB()
   On Error GoTo errLbl
   
   Dim objIE As InternetExplorer
   Dim sh1 As Worksheet
   
   Set sh1 = ThisWorkbook.Sheets("ZB")
   sh1.Range("2:" & Rows.Count).ClearContents
   
   Set objIE = New InternetExplorer
   objIE.Visible = True
     
   'Open url
   objIE.Navigate "http://www.cmegroup.com/trading/interest-rates/us-treasury/30-year-us-treasury-bond.html"
     
   'Loop until ie page is fully loaded
   Do Until objIE.ReadyState = READYSTATE_COMPLETE
      DoEvents
   Loop
   
   With objIE.Document
      tabsNum = .all.tags("table").Length
      
      myTab = 21
      
      'wait for datas
      Do
         mytext = .all.tags("table")(myTab).Rows(1).Cells(10).innertext
      Loop While mytext = "-"
      
      rowsNum = .all.tags("table")(myTab).Rows.Length
      For r = 0 To rowsNum - 1
         cellsNum = .all.tags("table")(myTab).Rows(r).Cells.Length
         For c = 0 To cellsNum - 1
            sh1.Cells(r + 1, c + 1) = Replace(.all.tags("table")(myTab) _
                  .Rows(r).Cells(c).innertext, vbCrLf, vbLf)
         Next c
      Next r
   
   End With
   
   'use next instruction to close internet explorer object
   objIE.Quit

exitLbl:
   Set objIE = Nothing
   Set sh1 = Nothing
   Exit Sub

errLbl:
   MsgBox "An error occurred: " & Err.Number & " - " & Err.Description, vbOKOnly
   Resume exitLbl
End Sub

No problem with:

Sub tabel_uitlezen()
  With New InternetExplorer
    .Navigate "http://www.cmegroup.com/trading/interest-rates/us-treasury/30-year-us-treasury-bond_quotes_openOutcry.html"
        
    Do While .ReadyState <> 4
      DoEvents
    Loop
        
    With .Document
      sq = Cells(1, 1).Resize(.all.tags("table")(21).Rows.Length - 1, .all.tags("table")(21).Rows(1).Cells.Length)
          
      Do
        DoEvents
      Loop While InStr(.all.tags("table")(21).innerText, "'") = 0

      For j = 1 To UBound(sq)
        For jj = 1 To UBound(sq, 2)
          sq(j, jj) = Replace(.all.tags("table")(21).Rows(j - 1).Cells(jj - 1).innerText, vbCr, "")
        Next
      Next
    End With
  End With

  Sheets(1).Cells(1, 1).Resize(UBound(sq), UBound(sq, 2)) = sq
End Sub

You have to activate/check the reference (Menu Bar in VBEditor/Extra/references/Microsoft Internet Controls)