Nesting a loop within a loop error

I am trying to run a loop within a loop... i need 1 varaible to be satisfied so that then the main loop (nested one) starts and when its done the macro goes to the next cell down (z + 1) and performs the same loops there.

When I try this i get the following error occurs on the last line of the code:

Compile Error: Loop without Do

any idea how to fix this?

Heres the code:

Sub Calendar_Calc_Avgs()

Dim y As Long
Dim z As Long
Dim avgM
Dim countM As Long

y = 0
z = 20
avgM = 0
countM = 0

Do

If IsEmpty(Sheets("Averages").Range("B" & z)) = False Then

With Sheets("Calendar").Range("G4")

    Do

    If .Offset(y, 0) = Sheets("Averages").Range("B" & z) Then
         avgM = avgM + .Offset(y, -2)
         countM = countM + 1
    End If

    y = y + 1
    Loop Until .Offset(y, 1) = 1

End With

Sheets("Averages").Range("C" & z).Value = avgM / countM

z = z + 1

Loop Until Sheets("Averages").Range("C" & z).Offset(0, -1) = ""

End Sub

Hi there,

I think you've omitted an "End If" statement. Try the following code and see if it works:

Option Explicit


Sub Calendar_Calc_Avgs()

    Dim countM  As Long
    Dim y       As Long
    Dim z       As Long
    Dim avgM

    y = 0
    z = 20
    avgM = 0
    countM = 0

    Do

        If IsEmpty(Sheets("Averages").Range("B" & z)) = False Then

            With Sheets("Calendar").Range("G4")

                Do

                    If .Offset(y, 0) = Sheets("Averages").Range("B" & z) Then
                         avgM = avgM + .Offset(y, -2)
                         countM = countM + 1
                    End If

                y = y + 1

                Loop Until .Offset(y, 1) = 1

            End With

        End If          '   THIS STATEMENT WAS OMITTED FROM YOUR ORIGINAL CODE

        Sheets("Averages").Range("C" & z).Value = avgM / countM

        z = z + 1

    Loop Until Sheets("Averages").Range("C" & z).Offset(0, -1) = ""

End Sub

Hope this helps - please let me know how you get on.

Regards,

Greg M