Create 2 columns and populate variable data combinations

I hope you don't mind a mini novel:

Need to create a table based on 2 other tables.
The resulting table would consist of every combination (and vise versa) that the 2 source tables would create. For example:
Source data 1 located in column A (A2):
Blue
Red
Green
Orange

Source data 2 located in column L (L2)
Circle
Box
Triangle
Square
Rectangle

Both source data columns can have a variable number of entries.
Need to create the following data table on a different worksheet utilizing columns A and B
(Blue in col A, Circle in Column B in the example that follows):

Blue Circle
Blue Box
Blue Triangle
Blue Square
Blue Rectangle
Red Circle
Red Box
Red Triangle
Red Square
Red Rectangle
Green Circle
Green Box
Green Triangle
Green Square
Green Rectangle
Orange Circle
Orange Box
Orange Triangle
Orange Square
Orange Rectangle
Circle Red
Circle Blue
Circle Green
Circle Orange
Box Red
Box Blue
Box Green
Box Orange
Triangle Red
Triangle Blue
Triangle Green
Triangle Orange
Square Red
Square Blue
Square Green
Square Orange
Rectangle Red
Rectangle Blue
Rectangle Green
Rectangle Orange

In short: each combination of all the values from both columns would be represented in the new table.
The reason for this is to allow updating of a list to include new items and combinations of available products.
I've extracted the unique values from the new table. This works in a validation list dropdown on another sheet, where the user can enter a color, and an adjacent column will populate all the shapes associated with that color. The necessity of a macro is for the purposes of updating with additions and deletions from both data source tables. This macro can rebuild the table from scratch with each refresh. I can add a sorting provision, and code to adjust the named range fields.
I'm hoping that my approach to this is fundamentally sound, and workable. Just need a vehicle to make updating this workable. Other approaches would be certainly appreciated as well.
Thank you for your ideas.
Pete

This should do it:

Option Explicit

Sub MakeCombinations()
Dim RngA As Range
Dim RngL As Range
Dim aVal As Range
Dim Cnt  As Long
Dim NR   As Long

Application.ScreenUpdating = False

With ActiveSheet
    Set RngA = .Range("A2:A" & .Rows.Count).SpecialCells(xlConstants)
    Set RngL = .Range("L2:L" & .Rows.Count).SpecialCells(xlConstants)
    Cnt = WorksheetFunction.CountA(RngL)
End With

With Worksheets.Add
    NR = 1
    For Each aVal In RngA
        .Range("A" & NR).Resize(Cnt).Value = aVal.Value
        .Range("B" & NR).Resize(Cnt).Value = RngL.Value
        NR = NR + Cnt
    Next aVal
End With

Application.ScreenUpdating = True
End Sub

Jerry, thank you for the work on the code. It performs half of the matches. In other words, it takes column A, and applies an instance of column L for each value. Great! What also needs to happen, is that it should also take values from column L, and applies an instance of column A for each value. As it is in the OP, it starts with colors leading the combinations; entering values from L. Also needs to use column L first, in the example above referenceing shapes, and extends them down with a matching color.
Many thanks.
Pete

There's no need to "quote" my post into yours, it merely clutters your own thread. (unless you're pointing out/discussing a specific line or comment, that is.) Just use the Quick Reply option instead.

I had hoped you would take it on yourself to add the other section since it is merely a reversal of what we already did.

Option Explicit

Sub MakeCombinations()
Dim RngA As Range, RngL As Range, aVal As Range
Dim Cnt As Long, Cnt2 As Long, NR As Long

Application.ScreenUpdating = False

With ActiveSheet
    Set RngA = .Range("A2:A" & .Rows.Count).SpecialCells(xlConstants)
    Set RngL = .Range("L2:L" & .Rows.Count).SpecialCells(xlConstants)
    Cnt = WorksheetFunction.CountA(RngL)
End With

With Worksheets.Add
    NR = 1
    For Each aVal In RngA
        .Range("A" & NR).Resize(Cnt).Value = aVal.Value
        .Range("B" & NR).Resize(Cnt).Value = RngL.Value
        NR = NR + Cnt
    Next aVal
    
    Cnt = WorksheetFunction.CountA(RngA)
    For Each aVal In RngL
        .Range("A" & NR).Resize(Cnt).Value = aVal.Value
        .Range("B" & NR).Resize(Cnt).Value = RngA.Value
        NR = NR + Cnt
    Next aVal    
End With

Application.ScreenUpdating = True
End Sub

If that takes care of your need, please click EDIT in your original post, click GO ADVANCED and set the PREFIX box to SOLVED.