Error 424 when including declaration

[bk1]

Hi,
I have a weird problem with the following code. When the declaration of s is included, the program stops at the "For Each s" statement caliming to need an object. When I comment it out, the code runs error free and TypeName reports "s" to be of type "Worksheet".

Why does the code fail when the declaration of s is included?

Sub Patch_Label_Sheets(S1 As Worksheet, S2 As Worksheet, S3 As Worksheet, S4 As Worksheet)
'**************************************************************************
' Changes references so they point correctly to the new sheets
' Version:
'**************************************************************************
    
    Dim Sheets As Variant
    Dim names As Variant
    Dim xx As String
    Dim ss As Long
    Dim s As Worksheet		' When this declaration is commented out, and Option Explicit is not in,
				' the code runs error free!
    Dim i As Long  		
 
       
    Sheets = Array(S1, S2, S3, S4)
    xx = S1.Name
    
    names = Array("Unshipped items", "Shipping table", "Label report", "Confirmation report")
    ss = LBound(Sheets)
    ss = UBound(Sheets)
    MsgBox TypeName(Sheets)
    
    For Each s In Sheets   	' When the above decalration is included, this statement fails,
				' with error 424 requiring an object

    MsgBox TypeName(s)	 	' when the code runs and s is reported to be of type 'Worksheet'

        For i = 0 To UBound(names)
            s.Cells.Replace What:="'x_" & names(i) & "'", Replacement:="'" & Sheets(i).Name & "'", LookAt:=xlPart, _
                SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
                ReplaceFormat:=False
        Next
    Next
End Sub

[Firefly2012]

I'm not sure if this is the reason but you definitely should rename your Sheets variable as this is the name of an existing Excel VBA collection so you may well get conflicts. Call it something else eg mySheets

[bk1]

Unfortunately, that did not help. However, I do agree with your general viewpoint :-)

[protonLeah]

Dim s as Variant

[bk1]

Much obliged :-) Thanks!!! That did the trick.

But why does it have to be a variant when each element of the array is a Worksheet object?Is this documented somewhere?

[protonLeah]

It's documented in Using Arrays in Help. You are iterating through a array, therefore, the control variable (element) must be of type Variant.
This works, yours did not:

Sub test()
    Dim Sht As Worksheet
    For Each Sht In ThisWorkbook.Sheets
        Debug.Print Sht.Name
    Next Sht
End Sub

so does:

Sub test()
Dim TestCell As Range

For Each TestCell In Range("A1:A10")
    Debug.Print TestCell.Address
Next TestCell
End Sub