Prompt for file name

Hi, The code below will save a xlsm file as a xlsx file using the same name. I need it to prompt me with the name highlighted in blue so I can change it slightly if needed before saving.

Can anyone help, thanks in advance.

Sub NewFile()
'
' NewFile Macro
'
' Keyboard Shortcut: Ctrl+n
'
    Dim sName As String
    
    With ThisWorkbook
        If Not .Saved Then Exit Sub
        sName = .FullName
        sName = Left(sName, InStrRev(sName, ".")) & "xlsx"
        Application.DisplayAlerts = False
        .SaveAs FileName:=sName, FileFormat:=xlOpenXMLWorkbook
    End With
End Sub

You could just use the Application.FileDialog to do this e.g:

 With Application.FileDialog(msoFileDialogSaveAs)
        .InitialFileName = ThisWorkbook.FullName
        If .Show = -1 Then
            .Execute
        Else
            Exit Sub
        End If
End With

You need to use the GetSaveasFilename dialog.

Sub X()
    Dim sName As String
    Dim vntFilename As Variant
    
    With ThisWorkbook
        If Not .Saved Then Exit Sub
        sName = .FullName
        sName = Left(sName, InStrRev(sName, ".")) & "xlsx"
        vntFilename = Application.GetSaveAsFilename(sName, "Excel Workbook (*.xlsx),*.xlsx")
        If Not vntFilename = False Then
            Application.DisplayAlerts = False
            .SaveAs Filename:=vntFilename, FileFormat:=xlOpenXMLWorkbook
        End If
    End With
End Sub