Moving data files from one directory to another

**ernies111** · 09-01-2012, 09:47 PM

Need to find a macro that can read data in columns in my Excel document ( which lists file names ) and move files from one directory to another. Any ideas?

**JBeaucaire** · 09-02-2012, 01:01 AM

Something like this to get you started:

Option Explicit

Sub MoveFiles()
Dim myPath As String, myDest As String
Dim MyFiles As Range, aFile As Range

myPath = "C:\Path\To\My\Files\"         'remember the \ at the end
myDest = "C:\Path\To\Put\My\Files\"     'remember the \ at the end

Set MyFiles = Sheets("Sheet1").Range("A:A").SpecialCells(xlConstants)

For Each aFile In MyFiles               'evaluate one filename at a time
    If Len(Dir(myPath & aFile.Value)) > 0 Then      'make sure file exists
        Name myPath & aFile.Value As myDest & aFile.Value
        aFile.Offset(, 1).Value = "Moved"
    Else
        aFile.Offset(, 1).Value = "Not Found"
    End If
Next aFile

End Sub

**ernies111** · 09-02-2012, 11:26 AM

Thank you. This is perfect!

**Cutter** · 09-02-2012, 12:28 PM

@ ernies111

Based on your last post it seems that you are satisfied with the solution(s) you've received but you haven't marked your thread as SOLVED. I'll do that for you now but please keep in mind for your future threads that Rule #9 requires you to do that yourself. If your problem has not been solved you can use Thread Tools (located above your first post) and choose "Mark this thread as unsolved".
Thanks.

Also, as a new member of the forum, you may not be aware that you can thank those who have helped you by clicking the small star icon located in the lower left corner of the post in which the help was given. By doing so you can add to the reputation(s) of those who helped.