Validating vb user form text box - help!

Hi, Beam_me_up,

a) check any entry into the box to be numeric

Private Sub uniqueref_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
    Select Case KeyAscii
        Case 48 To 57 
        Case Else
            KeyAscii = 0
    End Select
End Sub

Please try the following amendment to the code (untested):

Private Sub uniqueref_AfterUpdate()
lastrow = Cells(rows.Count, "A").End(xlUp).Row
If WorksheetFunction.CountIf(Range("A1:A" & lastrow), uniqueref) = 0 Then
  MsgBox "number does not exist!", vbInformation, "try again"
  With uniqueref
    .SetFocus
    .SelStart = 0
    .SelLength = Len(.Text)
  End With
  Exit Sub
Else
  findrow = Range("A1:A" & lastrow).Find(uniqueref.Value, Cells(1, 1)).Row
  For I = 1 To 6
    UserForm1.Controls.Item("TextBox" & CStr(I)).Value = Cells(findrow, I).Value
  Next I
End If
End Sub

Ciao,
Holger

Hi, Beam_me_up,

except the Set Focus. Not sure why.

Iīm afraid I donīt see a mistake on the spot. If there is no other code that may interfere: I will have to build an example, look at it, hopefully sort it out and come back with a solution.

Ciao,
Holger

Hi, Beam_me_up,

please apply uniqueref_Exit (starts on leaving the textbox and may be cancelled) instead of uniqueref_AfterUpdate (another control has the focus):

Private Sub uniqueref_Exit(ByVal Cancel As MSForms.ReturnBoolean)

lastRow = Cells(Rows.Count, "A").End(xlUp).Row

If WorksheetFunction.CountIf(Range("A1:A" & lastRow), uniqueref) = 0 Then
  MsgBox "number does not exist!", vbInformation, "try again"
  Cancel = True
  With uniqueref
    .SetFocus
    .SelStart = 0
    .SelLength = .TextLength
    End With
  Exit Sub
Else
  findRow = Range("A1:A" & lastRow).Find(uniqueref.Value, Cells(1, 1)).Row
  For I = 1 To 6
    UserForm1.Controls.Item("TextBox" & CStr(I)).Value = Cells(findRow, I).Value
  Next I
End If

End Sub

Ciao,
Holger

Hi, Beam_me_up,

strange I like to keep my numbers in ascending order.

  findRow = Range("A1:A" & lastRow).Find(What:=uniqueref.Value, After:=Cells(1, 1), Lookat:=xlWhole).Row

Ciao,
Holger