how can I create a macro which will check the selected criteria in filter?

Hi Anand. Try this:

Private Sub Workbook_Open()
Application.Calculation = xlAutomatic                   '// enable auto-calculate
Sheets("Sheet1").Protect UserInterfaceOnly:=True, AllowSorting:=True, AllowFiltering:=True
End Sub

Function FilterCriteria(iColms As Integer, iHead As Integer) As String

Dim cl As String, sCri As String, sAry As String   ' sets filter info for filter criteria bar
Dim arg As Variant                                 ' iColms is number of sort columns in table
Dim i As Integer                                   ' iHead is table header row

Application.Volatile True
On Error Resume Next
For i = 1 To iColms
    With ActiveSheet.AutoFilter.Filters(i)
        If .On Then
            sCri = IIf(Left(.Criteria1, 1) = "=", Right(.Criteria1, Len(.Criteria1) - 1), .Criteria1)
            If .Operator = xlAnd Then
                sCri = sCri & "  and  " & IIf(Left(.Criteria2, 1) = "=", Right(.Criteria2, Len(.Criteria2) - 1), .Criteria2)
            ElseIf .Operator = xlOr Then
                sCri = sCri & ", " & IIf(Left(.Criteria2, 1) = "=", Right(.Criteria2, Len(.Criteria2) - 1), .Criteria2)
            End If
            If Err.Number = 0 Then
                cl = cl & Cells(iHead, i + 2) & " : " & sCri & "        "
            Else
                sAry = ""
                For Each arg In .Criteria1
                    sAry = sAry & ", " & Right(arg, Len(arg) - 1)
                Next arg
                cl = cl & Cells(iHead, i + 2) & " : " & Right(sAry, Len(sAry) - 1) & "        "
                Err.Clear
            End If
        End If
    End With
Next i
With ActiveSheet.ClearFilter
    If cl = "" Then                                ' hide Clear Filter button
        FilterCriteria = "": .Visible = False
    Else                                           ' show Clear Filter button
        FilterCriteria = cl: .Visible = True
    End If
End With
End Function

Put this into a cell : FilterCriteria(# of columns in your table, Table Header row)

Where (# of columns in your table) is how many columns you have in your table.
And (Table Header row) is the row number that the table header is in.

Now as you change the filter in your table, the filter criteria will appear in the cell with the FilterCriteria() function.

Have a button on your page with the name "ClearFilter". Attach this code to the button :

ActiveSheet.ShowAllData

Pressing the button will clear the filter from your table.

Look over the attached file. In the Sub Workbook_Open(), comment out the line "Application.Calculation = xlManual" or set it to xlAutomatic... Should work like you want now. It has an additional capability to right click on any cell to apply a filter. This code does work with multiple criteria, maybe you need to adapt it a little to work with your table? But it should work. Please post back if not.

You should put into the Q5 (or any other cell you want) "=FilterCriteria(8,5)" ... because there are 8 columns in the table, and the table header is in row 5

Remember also ... in the Sub Workbook_Open(), comment out the line "Application.Calculation = xlManual" or set it to xlAutomatic

2 problems you're having. First, you have the file saved with the worksheet calculation set to manual, it must be set to automatic. In the Sub Workbook_Open() put in this line :

Application.Calculation = xlAutomatic

Second problem is that Q5 is on the right and maybe you can't see it. Go into Excel Options and activate the scrollbars, then you can see Q5. I have "=FilterCriteria(8,5)" above the table in cell B2