Generate worksheets from list of values and have each worksheet contain the same formula

Greetings,

I have a macro that creates worksheets based on the values in column A; 1 tab for each value with that value as the tabs name.

The next step, where I'm completely lost, is to have each of these new tabs be a copy of the "tab setup" worksheet with the value in cell B1 matching the tab name.

I've attached a workbook to help explain my desired outcome, any and all assistance is greatly appreciated.

tab setup for excel forum.xlsm


Current code is shown below:

Sub Generate_Tabs()

Dim strCol As String
Dim strRow As String
Dim rngStart As Range
Dim rngEnd As Range
Dim rngCell As Range
Dim strWsName As String
Dim strSrcName As String

On Error GoTo ErrHnd


strCol = "A"
strRow = "2"

Application.ScreenUpdating = False
            
strSrcName = ActiveSheet.Name

Set rngStart = ActiveSheet.Range(strCol & strRow)
Set rngEnd = ActiveSheet.Range(strCol & CStr(Application.Rows.Count)).End(xlUp)
            
For Each rngCell In ActiveSheet.Range(rngStart, rngEnd)
    If rngCell.Text <> "" Then
        strWsName = rngCell.Text
        On Error Resume Next
        If Worksheets(strWsName) Is Nothing Then
            On Error GoTo ErrHnd
            Worksheets.Add After:=Worksheets(Worksheets.Count)
            Worksheets(Worksheets.Count).Name = strWsName
            Else
            On Error GoTo ErrHnd
        End If
    End If
Next rngCell

Worksheets(strSrcName).Activate

Application.ScreenUpdating = True
Exit Sub

ErrHnd:
Err.Clear
Worksheets(strSrcName).Activate
Application.ScreenUpdating = True

End Sub

Why not copy the 'tab setup' sheet?

Sub Generate_Tabs()
Dim rngStart As Range
Dim rngEnd As Range
Dim rngCell As Range

    Application.ScreenUpdating = False

    strSrcName = ActiveSheet.Name

    Set rngStart = Worksheets("input").Range("A2")
    Set rngEnd = Worksheets("input").Range("A" & Application.Rows.Count).End(xlUp)

    For Each rngCell In Worksheets("input").Range(rngStart, rngEnd)
        If rngCell.Text <> "" Then
            strWsName = rngCell.Text

            Worksheets("tab setup").Copy after:=Worksheets(Worksheets.Count)

            With Worksheets(Worksheets.Count)
                .Name = strWsName
                .Range("B1").Value = .Name
            End With
        End If
    Next rngCell
    
End Sub

    Dim Rws As Long, Rng As Range, c As Range
    Dim sht As Worksheet
    Set sht = Worksheets("input")

    With sht
        Rws = .Cells(Rows.Count, "A").End(xlUp).Row
        Set Rng = Range(.Cells(2, 1), .Cells(Rws, 1))
    End With
    For Each c In Rng.Cells
        Sheets.Add(After:=Worksheets(Worksheets.Count)).Name = c
        Range("A1") = "ID": Range("A3") = "Name": Range("A4") = "Age": Range("B1") = c
        Range("B3") = c.Offset(0, 1): Range("B4") = c.Offset(0, 2)
    Next c

Thank you all! I'm running through each but they all appear to do exactly what I want.