OLE Object Array Declaration Syntax Problem

**beat** · 04-26-2013, 07:07 AM

I have 6 toggle buttons

Toggle1
Toggle2
Toggle3
etc

I am wondering if its possible to have them as an array?

option base 1

dim Tog(6) as(???) '<< Not sure on this bit
Tog(1)= Toggle1 
Tog(2)= Toggle2
Tog(3)= Toggle3 
#etc

for i = 1 to 6
select case Tog(i)
case true
range("A" & i ) = "YAY"
case false
range("B" & i ) = "nay"
end select
Next i

end sub

Thanks for an insight

Beat

**Kyle123** · 04-26-2013, 07:40 AM

Possibly:

Dim toggles(0 To 1) As MSForms.ToggleButton

Set toggles(0) = Me.ToggleButton1
Set toggles(1) = Me.ToggleButton2

**Colin Legg** · 04-26-2013, 08:02 AM

Sure, you can if you want to. If we keep the code the same as you presented it, it would be:

    Dim togs(1 To 6) As MSForms.ToggleButton
    Dim i As Long
    
    Set togs(1) = Toggle1
    Set togs(2) = Toggle2
    Set togs(3) = Toggle3
    Set togs(4) = Toggle4
    Set togs(5) = Toggle5
    Set togs(6) = Toggle6
    
    For i = LBound(togs) To UBound(togs)
        
        If togs(i).Value Then
            Range("A" & i).Value = "YAY"
        Else
            Range("B" & i).Value = "nay"
        End If
        
    Next i

There are various other options available to you too. For example, you could use the Userform's controls collection:

    Dim i As Long
    
    For i = 1 To 6
        If Controls("ToggleButton" & CStr(i)).Value Then
            Range("A" & i).Value = "YAY"
        Else
            Range("B" & i).Value = "nay"
        End If
    Next i

**beat** · 04-26-2013, 08:08 AM

Superb thanks,

ill give it a try

**snb** · 04-26-2013, 08:11 AM

in a userform:

Private sn

Private Sub UserForm_Click()
    MsgBox sn(0) & vbLf & sn(1) & vbLf & sn(2) & vbLf & sn(3)
End Sub

Private Sub UserForm_Initialize()
    ReDim sn(Controls.Count - 1)
    
    For j = 0 To UBound(sn)
        Set sn(j) = Me("checkbox" & j + 1)
    Next
End Sub