Lookup name in list

Hey,

I'm really bad in VBA, but I think its fun to try some things.
Got a script now so when someone types in a new range of info, it will be added in the datasheet

This datasheet looks like this:
[number] [name] [surname] [adress] [extrainfo]
[1] [Frans] [Flipkip] [whocares] [ ]
[2] [Tony] [Mafkees] [noidea] [ ]

When I have Flipkip on my first page in a cell (say A1) <-- this cell is always the same
And info in cell A2
Then I want, when I press a button, to return the info from cell A2 into datasheet extrainfo column in row 2

When I have Mafkees on my first page in a cell (say A1)
And info in cell A2
Then I want, when I press a button, to return the info from cell A2 into datasheet extrainfo column in row 3

If someone tells me to upload an example I will have to disappoint him/her. My sheet is so confusing that I can better just try and explain it, so I have 2% chance someone will understand it and is willing to help.

Create a module in your workbook and add the following code:

Public Sub copyInfo()
On Error Resume Next

'#
'# declare private variables
'#
   Dim strLookupKey As String
   Dim strExtraInfo As String
   Dim objFound As Excel.Range

'#
'# assuming sheet1 is the input worksheet containing cell A1 and A2 as per
'# your example
'#
   With ThisWorkbook.Worksheets("Sheet1")
      strLookupKey = .Range("A1").Value
      strExtraInfo = .Range("A2").Value
   End With
   
'#
'# search for the lookup_value in the data worksheet, assuming the data worksheet is called
'# Sheet2 and the search must be performed in column C - using the column layout as described
'# in your post
'#
   With ThisWorkbook.Worksheets("Sheet2")
   
   '#
   '# conduct a search; when the search argument is found, the objFound range object will contain a pointer
   '# to the cell in column C holding the argument searched - you can play with the parameters to make the
   '# search more or less restrictive (match case, whole or partial cell value matching etc)
   '#
      Set objFound = .Cells.Find(What:=strLookupKey, After:=Cells(1, "C"), LookIn:=xlValues, LookAt:=xlWhole, _
                        SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:=True, SearchFormat:=False)
      
   '#
   '# if the search text was found, the target column (extra info) can be updated with the extra info provided in
   '# cell A2 - the cell to update can be found by moving two columns to the right from the cell holding the found
   '# search argument
   '#
      If Not objFound Is Nothing Then
         objFound.Offset(0, 2).Value = strExtraInfo
      Else
         MsgBox "Sorry but the name " & Chr$(34) & strLookupKey & Chr$(34) & " could not be found"
      End If
      
   End With

End Sub

Add a button object to your first worksheet and subsequently link the button to the above routine - change the names of the worksheets in the code provided to meet your requirements