Deleting columns

Any one else bored today that can help with this simple issue. I need to be able to delete column 47 (AU) and its entire contents immediately after running this piece of code

Sub Delete_Rows()
Dim rng As Range, cell As Range, del As Range
Set rng = Intersect(Range("A1:AT150"), ActiveSheet.UsedRange)
For Each cell In rng
If (cell.Value) = "Grade-B" _
Then
If del Is Nothing Then
Set del = cell
Else: Set del = Union(del, cell)
End If
End If
Next cell
On Error Resume Next
del.EntireRow.Delete
End Sub

Maybe it could be added to this piece of code it that's any easier.

I know it's Christmas but if you're bored like me then i'd appreciate your help.

Regards
John

Try add

Columns(47).Delete

at the end of your code

Sorry i forgot to mention that the code runs in the second worksheet called 'new' and the column that needs to deleted is in the first worksheet called 'Desktop'

In that case, try this:

Sub Delete_Rows()

    Dim ws1 As Worksheet: Set ws1 = ThisWorkbook.Sheets("new")
    Dim ws2 As Worksheet: Set ws2 = ThisWorkbook.Sheets("Desktop")
    Dim rng As Range, cell As Range, del As Range
    
    Set rng = Intersect(ws1.Range("A1:AT150"), ws1.UsedRange)
    
    For Each cell In rng
        If cell.Value = "Grade-B" Then
            If del Is Nothing Then
                Set del = cell
            Else
                Set del = Union(del, cell)
            End If
        End If
    Next cell
    
    If Not del Is Nothing Then del.EntireRow.Delete
    
    ws2.Columns("AU").Delete
    
End Sub

Thanks to all, I used the code berlan provided and it did the trick. Many thx. (rep added)