If month and year of a date in a range of dates matches a specific date, return true

[btb918]

What I have is kind of close and I enter it as an array formula. The only problem with what I have is that if one date in the range has the correct year and another date in the range has the correct month it returns "True" even though one date in the range may not contain the correct year and month in itself.

Here is what I have so far:

=IF(AND(YEAR(F3:F7)=YEAR(A1)),(MONTH(Detailed!F3:F7)=MONTH(A1)),"True","False")

Thanks

[Jonmo1]

You can't use AND in an array formula like that.
AND can only evaluate single value arguments like Year(F1)=Year(A1)

Try

=IF(SUMPRODUCT((YEAR(F3:F7)=YEAR(A1))*(MONTH(F3:F7)=MONTH(A1))),"True","False")

[btb918]

That works really well except if a cell in the range of dates is blank. How would you remedy that?

[Jonmo1]

In what way does that cause it to not work?
Blanks would be considered 0, with a month of January and a year of 1900.

So unless A1 is also blank, or a date in January 1900, then it would have no effect.

[btb918]

It works if one of the cells in the range is truly blank, but if one is actually ="" then it returns #VALUE! for me

[Jonmo1]

Try

=IF(SUMPRODUCT(--(TEXT(F3:F7,"mmmyyyy")=TEXT(A1,"mmmyyyy"))),"True","False")

[btb918]

You're really good at this, but what if I have a date in cell A1 and another date in cell A2 and want to know if there is a date in the range of dates thats month matches A1 and year matches A2? I don't see how I can separate the year and date between two cells in your newest solution.

[Jonmo1]

Why on earth would you need to do that?
Just curious, I don't see any need for that.

But you can do it like this
=IF(SUMPRODUCT(--(TEXT(F3:F7,"mmmyyyy")=TEXT(A1,"mmm")&TEXT(A2,"yyyy"))),"True","False")

[btb918]

I have a list of stuff that has dates to be re-calibrated so thats the range of dates I've been talking about. I am trying to make a spreadsheet listing the items vertically and the months of the year horizontally. I just want a cell to say "DUE" in the correct month column relating to when a certain item is due for re-calibration in the current year. Its probably not the best way to go about it but I wanted to learn some new tricks.
I think that last one works perfectly! Thanks so much.

[Jonmo1]

You're welcome.