Macro to Batch/Mass Edit Headers/Footers on Multiple Word Documents (.docx) - Replace Text

I need to edit the Headers on 37 documents and change the same phrase of text. I need a macro that finds a standard text phrase among the 37 word documents and replace it with a specific text phrase.

I located a decent Macro that will edit the Body of the text but it won't change the header or footers (link below)

http://www.extendoffice.com/document...ple-files.html

Which points in the Macro do I need to add my inputs - which section do I put what I want to find and which section do I put what I need to replace?

I'm getting a ByRef argument type mismatch error when I use this code. Thoughts?

Hi,

The Rng in Call RngFndRep(Rng, Fnd, Rep) is highlighted. What do you mean by "how do you run the code"? This happens if I run it from the developer window, or if I run it via "compile" within the VBA windo

From within Word. Thanks!

That did the trick, good eye. It works perfectly for me now. Thanks!

As coded, it processes every possible range in a document, but the comments indicate what can be deleted to restrict processing to, say, just the headers.

Not sure what to delete, to make this work on just headers. The macro runs but nothing changes in my document headers

Ah, obvious now you explian, thanks for that, not very good with macros.
It was my error it didn't work, copied the text to replace from the header, but included a space by mistake.
Works perfectly now, saved me hours of work, so thank you so much!

So I've got the macro working, I'll select the folder with all the documents in it and I can watch in file explorer as it opens each file. However, it will perform the change on some of the files and not the rest. I move the updated files to another folder and run the macro again. Again, it will update some of the files it didn't the first round, but not all of them. I keep doing this until all the files have been updated.

Can anyone tell me what's going on and how to get it to do all the files with one run of the macro?

BTW, thanks for the code.

macropod,
Thanks for the feedback. The file I am running the macro from is in a different folder than the files I'm trying to update. One of the files was giving me a message along the lines of "The author has requested the file be opened read only...", but it was at the bottom of the list and I moved it into a different folder and updated it manually. The number of files it would process each time varied, the first time 12 files, then 5 files, then 8 files, then 3 files. The files are located in a folder on my local hard drive, not over the network on in the cloud. I just didn't know if maybe there was a specific reason it would do this.

Thanks, I'll poke around and see if I can figure it out.

Hi Could you please share the final code that worked for u?

I inserted the VBA below code in Word. I am able to select the folder with word documents, but nothing happens after that.. I need to change instances of 2018 to 2019. This is most probably in the footer and very rarely in the pages.

I don't have any knowledge about VBA code.

Sub UpdateDocuments()
Application.ScreenUpdating = False
Dim strFolder As String, strFile As String, wdDoc As Document, Rng As Range
Dim Sctn As Section, HdFt As HeaderFooter, Fnd As String, Rep As String
Fnd = "Find Text": Rep = "Replace Text"
strFolder = GetFolder
If strFolder = "" Then Exit Sub
strFile = Dir(strFolder & "\*.doc", vbNormal)
While strFile <> ""
Set wdDoc = Documents.Open(FileName:=strFolder & "\" & strFile, AddToRecentFiles:=False, Visible:=False)
With wdDoc
'Process everything except headers & footers
For Each Rng In .StoryRanges
Select Case Rng.StoryType
Case wdPrimaryFooterStory, wdFirstPageFooterStory, wdEvenPagesFooterStory, _
wdPrimaryHeaderStory, wdFirstPageHeaderStory, wdEvenPagesHeaderStory
Case Else
Call RngFndRep(Rng, Fnd, Rep)
End Select
Next
'Process headers & footers
For Each Sctn In .Sections
'Process headers
For Each HdFt In Sctn.Headers
With HdFt
If .LinkToPrevious = False Then
Call RngFndRep(HdFt.Range, Fnd, Rep)
End If
End With
Next
'Process footers
For Each HdFt In Sctn.Footers
With HdFt
If .LinkToPrevious = False Then
Call RngFndRep(HdFt.Range, Fnd, Rep)
End If
End With
Next
Next
.Close SaveChanges:=True
End With
strFile = Dir()
Wend
Set wdDoc = Nothing
Application.ScreenUpdating = True
End Sub

Function GetFolder() As String
Dim oFolder As Object
GetFolder = ""
Set oFolder = CreateObject("Shell.Application").BrowseForFolder(0, "Choose a folder", 0)
If (Not oFolder Is Nothing) Then GetFolder = oFolder.Items.Item.Path
Set oFolder = Nothing
End Function

Sub RngFndRep(Rng As Range, Fnd As String, Rep As String)
With Rng.Find
.ClearFormatting
.Replacement.ClearFormatting
.Format = False
.Forward = True
.Wrap = wdFindContinue
.Text = Fnd
.Replacement.Text = Rep
.MatchCase = True
.MatchAllWordForms = False
.MatchWholeWord = False
.MatchWildcards = False
.Execute Replace:=wdReplaceAll
End With
End Sub

Thanks for the code!!

I have the same problem as tmilburn. When I ran the code it only worked on some files and the number of files that works each time seems pretty random. Has anyone come across any potential solutions?

Oh lol. Sorry I completely missed the whole second page. Thanks!