Using DVAR

How about instead ...

	E	F	G
2	Critera	VAR
3	A	1128.7	F3: {=VAR(IF($A$2:$A$360=E3, $B$2:$B$360))}
4	B	339.4
5	C	627.7
6	D	1713.7
7	E	1295.2
8	F	1116.2

You're welcome.

Hi,

For an arrangement such as yours I would suggest using formula criteria with D-functions thus
Excel 2016 (Windows) 64 bit

	E	F	G	H
2	Criteria	VAR	DVAR	Formula Criteria
3	A	=VAR(B2:B21)	=DVAR($A$1:$B$360,2,H2:H3)	=A2=$E$3
4	B	=VAR(B22:B37)	=DVAR($A$1:$B$360,2,H3:H4)	=A2=$E$4
5	C	=VAR(B38:B64)	=DVAR($A$1:$B$360,2,H4:H5)	=A2=$E$5
6	D	=VAR(B65:B109)	=DVAR($A$1:$B$360,2,H5:H6)	=A2=$E$6
7	E	=VAR(B66:B109)	=DVAR($A$1:$B$360,2,H6:H7)	=A2=$E$7
8	F	=VAR(B213:B360)	=DVAR($A$1:$B$360,2,H7:H8)	=A2=$E$8

which will produce the following results
Excel 2016 (Windows) 64 bit

	E	F	G	H
2	Criteria	VAR	DVAR	Formula Criteria
3	A	1129	1129	TRUE
4	B	339	339	FALSE
5	C	628	628	FALSE
6	D	1714	1714	FALSE
7	E	1752	1295	FALSE
8	F	1116	1116	FALSE

Note that your existing calculation for E is incorrect as it is looking at the wrong range.

Alternatively, you might use a one-variable data table thus
Excel 2016 (Windows) 64 bit

	E	F	G	H
2		=DVAR($A$1:$B$360,2,H2:H3)		Criteria
3	A	=TABLE(,H3)		A
4	B	=TABLE(,H3)
5	C	=TABLE(,H3)
6	D	=TABLE(,H3)
7	E	=TABLE(,H3)
8	F	=TABLE(,H3)

to produce the same results
Excel 2016 (Windows) 64 bit

	E	F	G	H
2		1129		Criteria
3	A	1129		A
4	B	339
5	C	628
6	D	1714
7	E	1295
8	F	1116