+ Reply to Thread
Results 1 to 7 of 7

Finding growth when negative values occur.

  1. #1
    Forum Contributor
    Join Date
    01-27-2013
    Location
    United Kingdom
    MS-Off Ver
    Excel 2010
    Posts
    120

    Finding growth when negative values occur.

    Hi,

    I wondered if anybody could assist with the following:

    I am running the following formula to calculate growth over a series of values over a number of years:

    =(J2/B2)^(1/8)-1

    The problem is if J2 or B2 are -ve values the formula returns #NUM!
    B2 is the first value.
    J2 is the last value.

    Is there a way to ask the formula to skip B2 and move to C2 (assuming this is +ve) and use this value instead.
    Similarly wit J2, could the previous value be used by the formula?

    It is easier to understand in the attached file where I have put the calculations in.
    Maybe there is a different way of calculating growth over a period. If both values are -ve, then the resultant growth value is +ve which is incorrect.

    Terry
    Attached Files Attached Files

  2. #2
    Forum Expert José Augusto's Avatar
    Join Date
    10-29-2014
    Location
    Portugal
    MS-Off Ver
    2013-2016
    Posts
    3,329

    Re: Finding growth when negative values occur.

    Try
    =ABS(J2/B2)^(1/8)-1

  3. #3
    Forum Expert
    Join Date
    06-08-2012
    Location
    Left the forum!
    MS-Off Ver
    Left the forum!
    Posts
    5,189

    Re: Finding growth when negative values occur.

    Doing anything like that is going to give false results.

    The most sensible method that I have seen suggests posting negatives as "Profit" or "Loss" with no % figure.

    Try this in L2

    =IFERROR(IF(AND($J$2<0,INDEX($B$2:$I$2,ROWS($L$2:L2))<0),"Loss",($J$2/INDEX($B$2:$I$2,ROWS($L$2:L2)))^(1/(8-ROWS($L$2:L2)+1))-1),"Profit")

    Then fill down to L9 for the growth for all periods from 8 years down to 1. See if that gives the results you need.

  4. #4
    Forum Expert shg's Avatar
    Join Date
    06-20-2007
    Location
    The Great State of Texas
    MS-Off Ver
    2003, 2010
    Posts
    40,678

    Re: Finding growth when negative values occur.

    If you want growth over the rightmost stretch of positive numbers,

    A
    B
    C
    D
    E
    F
    G
    H
    I
    J
    K
    L
    M
    N
    O
    P
    1
    Period
    -8
    -7
    -6
    -5
    -4
    -3
    -2
    -1
    0
    From Pd
    To Pd
    Growth
    2
    Income
    (61)
    991
    1,260
    959
    176
    752
    943
    958
    884
    3
    10
    -1.62%
    L2: =IFERROR(LOOKUP(9E+307, COLUMN(A2:INDEX(2:2, M2))/(A2:J2 < 0) + 1), COLUMN(B2))
    3
    Income
    (61)
    (61)
    1,260
    959
    176
    752
    943
    958
    884
    4
    10
    -5.74%
    M2: =LOOKUP(9E+307, COLUMN(A2:J2)/(A2:J2 > 0))
    4
    Income
    (61)
    (61)
    1,260
    959
    176
    752
    (61)
    958
    884
    9
    10
    -7.72%
    N2: =(INDEX(2:2, M2)/INDEX(2:2, L2)) ^ (1/(M2-L2)) - 1
    5
    Income
    959
    991
    1,260
    959
    176
    752
    943
    958
    884
    2
    10
    -1.01%
    6
    Income
    (61)
    (61)
    1,260
    959
    176
    752
    943
    958
    (61)
    4
    9
    -5.33%
    7
    Income
    (61)
    (61)
    1,260
    959
    176
    752
    943
    (61)
    (61)
    4
    8
    -6.99%
    8
    Income
    (61)
    (61)
    (61)
    (61)
    (61)
    (61)
    943
    (61)
    (61)
    8
    8
    #DIV/0!
    Last edited by shg; 07-21-2018 at 02:02 PM.
    Entia non sunt multiplicanda sine necessitate

  5. #5
    Forum Contributor
    Join Date
    01-27-2013
    Location
    United Kingdom
    MS-Off Ver
    Excel 2010
    Posts
    120

    Re: Finding growth when negative values occur.

    Thanks, that works well.
    Terry

  6. #6
    Forum Contributor
    Join Date
    01-27-2013
    Location
    United Kingdom
    MS-Off Ver
    Excel 2010
    Posts
    120

    Re: Finding growth when negative values occur.

    Thanks for that. It was a lot more than I was expecting.
    Great stuff - I really appreciate the effort and time you have put in.

    Best regards
    Terry

  7. #7
    Forum Expert
    Join Date
    06-08-2012
    Location
    Left the forum!
    MS-Off Ver
    Left the forum!
    Posts
    5,189

    Re: Finding growth when negative values occur.

    Who was that reply directed at, Terry?

    I'm not trying to criticise the suggestions made by the others, but both could return misleading results.

    Using ABS() as suggested by Jose will skew the results, -1,000,000 in year 8 should be a greater growth than -100,000 when compared to the current positive figure, yet using ABS will show the opposite, the largest growth will come from the negative closest to 0 as the formula will evaluate the same figure as positive.

    shg's method gives more accurate results by eliminating the negatives, but you would need to align any data headings with the results correctly. Showing the results against the wrong periods by skipping over values could again be misleading when you analyse the figures. Although this is by far the most accurate method suggested here.

    My suggestion is becoming more unconvincing every time I look at it, there are certian pairings where it shows profit / loss where I think a % change should be shown, most notably when both values are negative.
    Last edited by jason.b75; 07-21-2018 at 05:53 PM.

+ Reply to Thread

Thread Information

Users Browsing this Thread

There are currently 1 users browsing this thread. (0 members and 1 guests)

Similar Threads

  1. Correct formula for negative numbers growth
    By Simeonov in forum Excel Formulas & Functions
    Replies: 2
    Last Post: 06-07-2018, 04:55 AM
  2. Replies: 6
    Last Post: 05-13-2017, 02:14 PM
  3. [SOLVED] Finding and summing up negative values
    By paradise2sr in forum Excel Formulas & Functions
    Replies: 4
    Last Post: 12-05-2015, 12:31 AM
  4. Replies: 8
    Last Post: 11-24-2015, 11:32 AM
  5. Finding CAGR compounded annual growth rate
    By jonnyyyl in forum Excel General
    Replies: 4
    Last Post: 02-06-2012, 09:19 PM
  6. Finding simple average growth rate
    By jonnyyyl in forum Excel General
    Replies: 3
    Last Post: 01-31-2012, 12:32 PM
  7. Help Finding if Names Occur Multiple Times
    By souljive99 in forum Excel General
    Replies: 1
    Last Post: 06-02-2009, 01:42 AM

Bookmarks

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts

Search Engine Friendly URLs by vBSEO 3.6.0 RC 1