Finding patterns in a list of numbers for EXCEL spreadsheet

Hello

I have a group of say 100 random integer numbers ranging from 0 to 40 (inclusive). (The numbers can repeat themselves)


I want Xcel to tell me
How many integers appeared consecutively as even numbers and odd numbers.

Also how many numbers appeared consecutively with a value as less than 20 and how many with a value greater than 20

Let the ZERO be both ODD/EVEN and have a value greater/less than 20 in any sequence.

Say numbers are:
5
23
39
2
0
2
2
0
15
19
33
31
33
and so on

In the example above :

2 and 3 integers appeared consecutively that were above the value of 20. That is the 23, 39 and the 33, 31, 33


3 and 6 integers appeared consecutively that were ODD. That is the 5, 23, 39 and the 0, 15, 19, 33, 31, 33


5 integers appeared consecutively that were EVEN. That is the 2, 0, 2, 2, 0



Thank you for your help


PS I haven't got a clue about how to use EXCEL really so if you can help me with which cell to insert which formula that would be great

Hi,

Zero is considered an even number, not odd.

Assuming your data is in A1:A13, these are all array formulas**:

Consecutive Even:

=IFERROR(SMALL(IFERROR(1/(1/(FREQUENCY(IF(ISEVEN(+A$1:A$13),ROW(A$1:A$13)),IF(1-ISEVEN(+A$1:A$13),ROW(A$1:A$13))))),""),ROWS(A$1:A1)),"")

Consecutive Odd:

=IFERROR(SMALL(IFERROR(1/(1/(FREQUENCY(IF(ISODD(+A$1:A$13),ROW(A$1:A$13)),IF(1-ISODD(+A$1:A$13),ROW(A$1:A$13))))),""),ROWS(A$1:A1)),"")

Consecutive >20:

=IFERROR(SMALL(IFERROR(1/(1/(FREQUENCY(IF(A$1:A$13>20,ROW(A$1:A$13)),IF(A$1:A$13<=20,ROW(A$1:A$13))))),""),ROWS(A$1:A1)),"")

Copy all down until you start to get blanks for the results.

Regards


**Array formulas are not entered in the same way as 'standard' formulas. Instead of pressing just ENTER, you first hold down CTRL and SHIFT, and only then press ENTER. If you've done it correctly, you'll notice Excel puts curly brackets {} around the formula (though do not attempt to manually insert these yourself).

Ok, so if the 13 numbers you give in your original post are listed vertically in cells A1:A13, then you can put the 3 formulas I gave you in say C1, D1 and E1.

Read the instructions carefully which I gave about how to enter an array formula. It can take a bit of getting used to at first, but once you've done it right (and so can see the curly brackets around the formula) for the formulas in C1, D1 and E1, copy (or drag) those formulas down a dozen cells or so. You may need to copy them further to cover all possible returns, but that should be easy enough to work out.

Cheers