average values per day from data with different dates

Originally Posted by Glenn Kennedy

One way:

Dates:
=UNIQUE(FILTER(INT(A2:A100),A2:A100<>""))

Average (copied across):
=AVERAGEIFS(B:B,B:B,"<>0",$A:$A,">="&$G3#,$A:$A,"<"&$G3#+1)

similarly for min & max. see file.

Thanks for your help but can I make the date of day calculations start from 8 am and end at 8 am in next date day as example the d ay 21 start at 8 am 21 and end 22 am and the day 22 start at 8 am and end at 8 am 23 etc and can making this in the the file attach up

I am sorry bu can give me the formula to make it if I have a lot of data in 30 day in month

Please have any method else unique formula because my 365 not update from it so any solution

i have office 365 but the version is 1.910 and the UNIQUE & FILTER Formula start work from version 1.911 and updates closed from It in my company so any other way to do this else using UNIQUE & FILTER formula with my best regrades

For averages

=AVERAGEIFS(B:B,$A:$A,">=" &$E3+8/24,$A:$A,"<" &$E3+32/24,B:B,"<>0")

For MIN

=AGGREGATE(15,6,(B:B)/((B:B>0)*($A:$A>=$E3+8/24)*($A:$A<$E3+32/24)),1)

for MAX

=AGGREGATE(14,6,(B:B)/((B:B>0)*($A:$A>=$E3+8/24)*($A:$A<$E3+32/24)),1)

thanks very much worked but if i want count how can do this

thanks i solved its

in O3

=COUNTIFS($A:$A,">=" &$E3+8/24,$A:$A,"<" &$E3+32/24,B:B,"<>0")