Pulling Specific Data Points from Datasets that are Time Dependent

kmersch,
Can you better define your terms and explain more for dim bulbs like me? You mention "the first hold in pressure". Looking in your sample data 1 I see "Time" and "Value". Is "Value" the first hold in pressure, so T1 initially is 09:48:26.710, and T2 is 09:48:26.809?

You mention "the timestamp of the very last data point at a the first hold in pressure and the timestamp of the very first data point at the second hold in pressure" which sounds like there are multiple data points each hold of pressure. What Data Points are you talking about? Is that the Value, and "first hold in pressure" is something else?

This proposal employs two helper columns which may be moved and/or hidden for aesthetic purposes.
The INT column is populated using: =INT(B12)
The Ramp Up column is populated using: =AND(C13=D$3,C14>D$3,AVERAGE(C14:C19)>D$3)
The calculations in D3:D5 are needed because the temp doesn't always fall to the same INT
D3: =MIN(C12:C3130)
D4: =MAXIFS(C12:C3130,A12:A3130,">="&INDEX(A12:A3130,MATCH(D3,C12:C3130,0)))
D5: =MINIFS(C12:C3130,A12:A3130,">"&F4)
The formulas in F3:F6 yield the times of T1:T4 respectively
F3: =INDEX(A12:A3130,MATCH(TRUE,D12:D3130,0))
F4: =INDEX(A12:A3120,AGGREGATE(15,6,(ROW(A12:A3130)-ROW(A11))/(A12:A3130>F3)/(C12:C3130=D4),1))
F5: =INDEX(A12:A3120,AGGREGATE(14,6,(ROW(A12:A3130)-ROW(A11))/(A12:A3130>F4)/(C12:C3130=D4),1))
F6: =INDEX(A12:A3120,AGGREGATE(15,6,(ROW(A12:A3130)-ROW(A11))/(A12:A3130>F5)/(C12:C3130=D5),1))
Let us know if you have any questions.

JeteMc,

Thank you very much for your help I was very excited to see this work, however, I have been pouring over some data and unfortunately this method isn't 100% accurate over all of the data sets the I have collected. In certain data sets the MAXIFS and MINIFS formula would pull data from outside of the "ramp band" during a hold in pressure. This is because the unit under test does a short ramp to try and maintain a pressure within a certain range, which throws off the validity of using the MAXIFS and MINIFS statements.

I was wondering if you would be able to help me work through one more thing. I thought about using the switch function as I have returned True/False based on the ramp rate of the data. This seems to be a more reliable method for me over the variety of data that I have.

Basically my goal is to return the first 'TRUE' as T1, and the first 'FALSE'> T1 as T2. This is then repeated for T3 & T4 (First 'TRUE'>T2 and first 'FALSE'>T3). I have been unable to figure out a good way to return the time stamp in C.olumn A based on the switching of values in Column D

I have attached the worksheet I have been working on to this thread.

Thank you very much for your help!

kmersch

Perhaps the following will help.
Populate cells E14:E3011 using: =IF(D14<>D13,SUM(MAX(E$13:E13),1),"")
Populate I2:I5 using: =INDEX(A$12:A$3011,MATCH(ROWS(I$2:I2),E$12:E$3011,0))
Note that the original T1 value is placed in cell J2.
Let us know if you have any questions.

You're Welcome and thank you for the feedback. Please take a moment to mark the thread as 'Solved' using the thread tools menu above your first post. I hope that you have a blessed day.