How to remove numbers in the front

[callmeyewgor]

i have a document files like this, and i suspect that there will be many duplication with similar context but different number in front of the text.

1.INTRODUCTION
1.1.This RFP/Tender is to call for the supply, xxxx
1.2.It shall be in the interest xxx
1.3.Proposals/offers received directly xxxx
1.4.The bidder shall submit system xxx
2.SCOPE OF WORK
2.1.The bidder shall xxxx
2.1.1.The offered solution must xxxxxx 500k license

Hi, can you provide me a formula to remove ONLY the numbers in the front so that the first letter in the cell always start with TEXT, and whatever numbers is in the middle of the text shall remain.

Expecting Results:

INTRODUCTION
This RFP/Tender is to call for the supply, xxxx
It shall be in the interest xxx
Proposals/offers received directly xxxx
The bidder shall submit system xxx
SCOPE OF WORK
The bidder shall xxxx
The offered solution must xxxxxx 500k license

[Rick Rothstein]

Here is one way to do it...

=MID(A1,MIN(IF(ISNUMBER(FIND(MID(A1,ROW($1:$99),1),"ABCDEFGHIJKLMNOPQRSTUVWXYZ")),ROW($1:$99))),99)

NOTE: I don't have your version of Excel, so I cannot test it, but if it doesn't work directly, then click in the formula bar and press CTRL+SHIFT+ENTER and see if that makes it work.

[callmeyewgor]

Attachment 835340

I am sorry I can't share you the document
Thank you for the reply, but it seems like it doesn't work

[Gregb11]

If you're still on 2013, you can try this (Where your data starts in cell A1):

=RIGHT(A1,LEN(A1)-MIN(IFERROR(SEARCH({"a","b","c","d","e","f","g","h","I","j","k","l","m","n","o","p","q","r","s","t","u","v","w","x","y","z"},A1),""))+1)

I think you'll have to enter this as an Array formula, meaning instead of hitting ENTER after you put in the formula, you would hit Shift,Ctrl,Enter.

If you're on 365 now, there are probably other ways.

Also, in your example, your text always starts after a period. Is that always the case? If so, AND if you're on MS365, you could do this:

=TEXTAFTER(A1,".",-1,0,1)

[bebo021999]

With text in A1

Suppose there are no periods "." within the Text String.

=TRIM(RIGHT(SUBSTITUTE(A1,".",REPT(" ",255)),255))

Or, general

=MID(A1,AGGREGATE(15,6,SEARCH(CHAR(ROW(65:90)),A1),1),255)

[callmeyewgor]

Or, general

=MID(A1,AGGREGATE(15,6,SEARCH(CHAR(ROW(65:90)),A1),1),255)

this formula work quite well, i fixed the $65:$90, and work very pretty, thank you!!

[callmeyewgor]

Hi all I have attached the testing file, please kindly have a look

[Phuocam]

Or try this

=REPLACE(B3,1,IFERROR(AGGREGATE(15,6,FIND(CHAR(ROW($65:$90)),B3),1)-1,0),"")

[Rick Rothstein]

I'm guessing my formula did not work for you because you did not adjust it for the actual location of your data. Assuming the file you attached in Message #1 shows the actual location of your data, then this formula (probably needing to be committed with CTRL+SHIFT+ENTER and not just Enter by itself) should work (all I did is change my assumed A1 starting cell to your actual starting cell of B3)...

=MID(B3,MIN(IF(ISNUMBER(FIND(MID(B3,ROW($1:$99),1),"ABCDEFGHIJKLMNOPQRSTUVWXYZ")),ROW($1:$99))),99)

[callmeyewgor]

this formula work great!!!