Left/Right with multiple Find

Hello,

I have a column with control number (Text strings). These control numbers are not always identical but they all share the "-". I will like to apply a formula to will break them down the text string. I have the formula LEFT(A2,FIND("-",A2)-1) when I am looking to only pull the first breake down but I am wondering if there is a way to have a formula that can considered many "-".

Exemple below. I also included an excel sheet


Control #'S Breake down #1 Breake down #2 Breake down #3 Breake down #4 Breake down #5
111AA-222C-333BB 111AA 222C 333BB


I hope this tread is clear enough to be understood

Thank you

Try:
=TEXTSPLIT(A2,"-")

or(delete ALL expected results first):

=IFERROR(DROP(REDUCE("",A2:A8,LAMBDA(x,y,VSTACK(x,TEXTSPLIT(y,"-")))),1),"")

In B2 copied across and down:

=IFNA(LET(t,TEXTBEFORE("-"&$A2,"-",COLUMNS($B1:C1)),TEXTAFTER(t,"-",COLUMNS($B1:B1))),"")

Glad to have helped.

If that takes care of your original question, please choose Thread Tools from the menu link above and mark this thread as SOLVED.

Also, if you have not already done so, you may not be aware that you can thank anyone who offered you help towards a solution for your issue by clicking the small star icon (* Add Reputation) located in the lower left corner of the post in which the help was given. By doing so you can add to the reputation(s) of all those who offered help.

No problem with my formulae...

Ali's works fine with:

=IFNA(LET(t,TEXTBEFORE("-"&$A2&"-","-",COLUMNS($B1:C1)),TEXTAFTER(t,"-",COLUMNS($B1:B1))),"")

I spotted it immediately, as I made the same error yesterday!!

I forgot to add the extra &"-" - Glenn has added it for you above.

Thanks, but please mark the thread as solved as explained earlier. Thanks.