Multiple protections

Originally Posted by GuyB

Hi , is it possible to lock and unlock with protection passwords (all using same password) multiple sheets, in a workbook by using just one command or do they have to be all done individually?

Guy B

Hi GuyB

You will need a macro to do this, see details below.

If you want this just for 1 workbook put the macro into the Visual Basic Editor for that sheet, if you want it available for all workbooks you will need to put it into the visual basic editor for Personal.xls

Public Sub Unprotect_All()
Dim wks As Worksheet
Dim vPword As Variant
On Error Resume Next
For Each wks In ActiveWorkbook.Worksheets
With wks
.Unprotect vPword
Do While .ProtectContents
vPword = Application.InputBox( _
prompt:="Enter password for " & .Name, _
Title:="Unprotect sheets", _
Default:="", _
Type:=2)
If vPword = False Then Exit Sub 'user cancelled
.Unprotect vPword
Loop
End With
Next
End Sub

Public Sub Protect_All()
Dim wks As Worksheet
Dim vPword As Variant
vPword = Application.InputBox( _
prompt:="Enter Password: ", _
Title:="Protect sheets", _
Default:="", _
Type:=2)
If vPword = False Then Exit Sub 'user cancelled
For Each wks In ActiveWorkbook.Worksheets
wks.Protect vPword
Next
End Sub