Two numbers to add in cell

[millo_2k]

Hi there,

Really could do with help, with what I believe is a fairly simple formula but I'm not a massive user of excel (yet!).

I have columns that have two numbers - '3(2)', how can I add these together?

For example

Cell A3 - 3(2)
+
Cell B3 - 6(4)
=
Cell C3 - x(x)

Any ideas?

If this isn't possible, is there any other way of arriving at the result of one number and another in the brackets next to it?

Many many thanks

[ragulduy]

I suppose this would probably work:
=LEFT(A3,1)+LEFT(B3,1)&"("&MID(A3,3,1)+MID(B3,3,1)&")"

[ramananhrm]

=left(a3,1)+left(a4,1)&"("&substitute(right(a3,2),")","")+substitute(right(a4,2),")","")&")"

[Tony Valko]

Will the numbers always be 1 digit numbers?

Will any of the numbers be negative numbers?

[XOR LX]

Hi,

Assuming your first example is in cell A3, then, with B3 the active cell, go to Name Manager and define a new name viz:

Name: Add_Numbers

Refers to: =EVALUATE(SUBSTITUTE(SUBSTITUTE(Sheet1!A3,"(","+"),")",""))

Close and return to the sheet. Then, in cell B3 type:

=Add_Numbers

Copy down as required to give respective answers for entries in A4, A5, etc.

Regards

[AlKey]

This will do it:

=SUM(VALUE(LEFT(A3,1)),SUM(VALUE(LEFT(B3,1))))&"("&SUM(ABS(VALUE(RIGHT(A3,3))),ABS(VALUE(RIGHT(B3,3))))&")"

or this a little bit shorter:

=SUM(LEFT(A3,1),LEFT(B3,1))&"("&SUM(ABS(RIGHT(A3,3)),ABS(RIGHT(B3,3)))&")"

[Tanujkumar88]

Hi,

Try this formula work for all condtion.

Formula : -

=LEFT(A1,FIND("(",A1)-1)+LEFT(B1,FIND("(",B1)-1)&"("&MID(A1,FIND("(",A1)+1,LEN(A1)-FIND("(",A1)-1)+MID(B1,FIND("(",B1)+1,LEN(B1)-FIND("(",B1)-1)&")"

Thanks
Tanuj

[Tony Valko]

Since everyone else is taking a WAG, I may as well throw my suggestion into the ring!

Data Range

	A	B	C
3	3(2)	6(4)	9(6)
4	1.5(8.25)	2.5(1.75)	4(10)
5	200(-1)	-200(1)	0(0)
6	1000(10)	10(1000)	1010(1010)
7	2(3)	5(-4)	7(-1)

This array formula** entered in C3 and copied down:

=SUM(--LEFT(A3:B3,FIND("(",A3:B3)-1))&"("&SUM(--MID(SUBSTITUTE(A3:B3,")",""),FIND("(",A3:B3)+1,15))&")"

** array formulas need to be entered using the key
combination of CTRL,SHIFT,ENTER (not just ENTER).
Hold down both the CTRL key and the SHIFT key
then hit ENTER.

Assumes EVERY cell will contain a number in parentheses and there will always be a number to the left of the parentheses.