AVERAGEIFS, LARGE, and SMALL

So I'm having an issue with my entire workbook. I thought I had the AVERAGE column figured out using AVERAGEIFS but it didn't work correctly, either. I have attached the workbook with my data.

The first sheet has my OBJECTIVE data which will be calculated from values in the second sheet, the DATA SET. In the first row of data on the first sheet I have what the correct values should be for the given NAME.

My objectives:

LENGTH: This column needs to take the largest value in the DATA SET for the given NAME and subtract from it the smallest value for that NAME in the DATA SET, returning the total length
AVERAGE DENSITY: This columns needs to return the average of the DENSITY values for a given NAME in the DATA SET
DAYS: This column is much like the LENGTH column, only using the DAYS data instead of LENGTH
COUNTY: What I would like to return in this column is an abbreviated version of the COUNTY name using the first three letters (i.e., SUS for Susquehanna)

Any help would be appreciated, please let me know if I need to further clear any of this up.

Dummy Data.xlsx

Hi
b2 cell (is an array)
=INDEX(Table1[Length],LARGE(IF(A2=Table1[Name],ROW(Table1[Name])-1,""),1))-INDEX(Table1[Length],SMALL(IF(A2=Table1[Name],ROW(Table1[Name])-1,""),1))

c2 cell
=AVERAGEIF(Table1[Name],A2,Table1[Density])

d2 cell (is an array)
=INDEX(Table1[Days],LARGE(IF(A2=Table1[Name],ROW(Table1[Name])-1,""),1))-INDEX(Table1[Days],SMALL(IF(A2=Table1[Name],ROW(Table1[Name])-1,""),1))

e2 cell
=INDEX(Table1[County],MATCH(A2,Table1[Name],0))

If the formula is an array then hit Ctrl Shift Enter after editing formula

For example
if ine of the "ROSIEMAR SUS 3H" 's density numbers left blank in Data sheet Avarageif will take to calculation. Depending on how your data is set formulas may show different results. All the formulas above considers that all data is available.

Or you could try these regular formulas, copied down...

B2=OFFSET('Data Set'!$A$1,MATCH($A2,'Data Set'!$A:$A,0)-1+COUNTIF('Data Set'!$A:$A,$A2)-1,1) - INDEX('Data Set'!B:B,MATCH($A2,'Data Set'!$A:$A,0))
C2=AVERAGEIF('Data Set'!$A:$A,$A2,'Data Set'!$C:$C)
D2=OFFSET('Data Set'!$A$1,MATCH($A2,'Data Set'!$A:$A,0)-1+COUNTIF('Data Set'!$A:$A,$A2)-1,3) - INDEX('Data Set'!D:D,MATCH($A2,'Data Set'!$A:$A,0))

edit: I hate the structured way excel uses on formulas in a table, so I just type in the values