Finding lowest cost carrier among an arry.

Hi. Ties results sometimes make a mess of "simpler" formulae

This array formula to return the minimum cost:
=MIN(IF($A$3:$A$7="Bronze",$B$3:$K$7))

and this array formula to return the cheapest provider:
=INDEX($B$2:$K$2,SUMPRODUCT(($B$3:$K$7=$B$11)*(COLUMN($B$3:$K$7)-COLUMN($B$3)+1)))
fall over when tied results are encountered. If this is not possible, fine.

However, to cover for possible ties in rows and columns, some more elaborate formulae are required. It's made even messier by the fact thta your table contains a mix of numbers and text.

To return the cheapest cost, an array formula:
=MIN(IFERROR(IF($A$3:$A$7="Bronze",$B$3:$K$7+(COLUMN($B$3:$K$7)/10^10)+ROW(B3:K7)/10^6),10^10))

but if bronze and bronze plus are BOTH to be considered:
=MIN(IFERROR(IF(ISNUMBER(SEARCH("Bronze",$A$3:$A$7)),$B$3:$K$7+(COLUMN($B$3:$K$7)/10^10+ROW(B3:K7)/10^6)),10^10))

and to return the cheapest carrier:
=INDEX($B$2:$K$2,SUMPRODUCT((IFERROR($B$3:$K$7+(COLUMN($B$3:$K$7)/10^10+ROW(B3:K7)/10^6),10^4)=$F$11)*(COLUMN($B$3:$K$7)-COLUMN($B$3)+1)))


All are array formulae.


Array Formulae are a little different from ordinary formulae in that they MUST be confirmed in the FIRST CELL ONLY by pressing CTRL+SHIFT+ENTER to activate the array, not just ENTER. After that, the array can be dragged down as normal, to cover the desired range.

You will know the array is active when you see curly brackets { } - or "curly braces" for those of you in the USA, or "flower brackets" for those of you in India - appear around the outside of your formula. If you do not use CTRL+SHIFT+ENTER you will (almost always) get an error message or an incorrect answer. Press F2 on that cell and try again.

Don't type the curly brackets yourself - it won't work...