sumif 2 conditions are met

a sample workbook would be very helpful but attached is my guess based on what you wrote...

=SUMIFS($B$2:$B$6,$C$2:$C$6,$F$1,$D$2:$D$6,"*dividend*")
see col E in attachment

As I mentioned in my post, a sample workbook with data AND expected results (hand entered) would be very helpful. It doesn't have to be a lot of data, just enough to show what you actually have and what you want.

So I'm reattaching the workbook with some adjustments that will give you a date range, and the amounts may be ridiculous but they are just examples to show you the formula and how it works.
=SUMIFS($B$2:$B$11,$C$2:$C$11,"<"&EOMONTH($F$1,0),$C$2:$C$11,">"&EOMONTH($F$1,-1),$D$2:$D$11,"*dividend*")

And if for example you put the word dividend in say cell G1 and interest in another cell you can alter the formula like this ...
=SUMIFS($B$2:$B$11,$C$2:$C$11,"<"&EOMONTH($F$1,0),$C$2:$C$11,">"&EOMONTH($F$1,-1),$D$2:$D$11,"*"&$G$1&"*")

just realized you might want it to include the last day of the month so adjust the "<" to "<=" to include the last day of the month for the first EOMONTH formula. You want it to be ">" for the other EOMONTH(F1,-1) so it only gets the current month.

well the formulas I gave you reference a date, I'm not really sure what you are asking for in post #7, remember I just mocked up a workbook based on a guess and what you wrote.
I mentioned in post #2 and again in #6 that a sample workbook would go a long way to getting you the formula you want/need.

Ok, if you want to eliminate the date and date reference but just want to focus on the match a word part then you would delete the sections in bold red...
=SUMIFS($B$2:$B$11,$C$2:$C$11,"<="&EOMONTH($F$1,0),$C$2:$C$11,">"&EOMONTH($F$1,-1),$D$2:$D$11,"*"&$G$1&"*")
so that you would just search for the word "dividend" in this case which I left in cell G1 so it would look like this...
=SUMIFS($B$2:$B$11,$D$2:$D$11,"*"&$G$1&"*")
in fact a sumif would work for that which would be... =SUMIF($D$2:$D$11,"*"&$G$1&"*",$B$2:$B$11)
or hardcoding in the word dividend then... =SUMIF($D$2:$D$11,"*dividend*",$B$2:$B$11)

your formula is not doing any "math", it is just looking for two texts in two different cells to return a value. I thought you were looking for a function to add up values that met criteria from two different columns.
you can get the same thing with other formulas too like ... =IF(AND(A2="Account A",ISNUMBER(SEARCH("DIV",E2))),B2,0) or this ... =IF(SUMIFS(B2,A2,"account a",E2,"*div*"),B2,0)
so if what you wrote gives you what you wanted, go with it, there isn't a right or wrong as long as you get the answer you are looking for as there are possibly dozens of formulas that might return the value you are looking for.