"Save As" folder -- can I default this to the same folder as origi

When I open up an Excel file using Windows Explorer, I sometimes want to use
"Save As" to change the name of the file (eg. new month extension, version 2,
etc.)

When I do this, Microsoft defaults to a different folder -- it is the folder
that I saved my last Excel file, which usually is a totally different folder.

Is there a way for me to have SAVE AS default to the same folder that the
current file is?

Any ideas is greatly appreciated! This has been quite annoying.

It sounds like you're using xl97. MS changed the behavior to offer to save to
the folder that contained the original with xl2k.

Maybe you can upgrade???

Or if it's just that single workbook, you can have a macro that does the
changing of folder.

Option Explicit
Sub testme01()

Dim mySavedPath As String

mySavedPath = CurDir

ChDrive ThisWorkbook.Path
ChDir ThisWorkbook.Path

Application.Dialogs(xlDialogSaveAs).Show

ChDrive mySavedPath
ChDir mySavedPath

End Sub

If your file is on a Network path (not mapped), you can use this instead. (In
fact, this works no matter what.)

Option Explicit
Private Declare Function SetCurrentDirectoryA Lib _
"kernel32" (ByVal lpPathName As String) As Long
Sub ChDirNet(szPath As String)
Dim lReturn As Long
lReturn = SetCurrentDirectoryA(szPath)
If lReturn = 0 Then Err.Raise vbObjectError + 1, "Error setting path."
End Sub
Sub testme02()

Dim mySavedPath As String

mySavedPath = CurDir

ChDirNet ThisWorkbook.Path

Application.Dialogs(xlDialogSaveAs).Show

ChDirNet mySavedPath

End Sub

Mike wrote:
>
> When I open up an Excel file using Windows Explorer, I sometimes want to use
> "Save As" to change the name of the file (eg. new month extension, version 2,
> etc.)
>
> When I do this, Microsoft defaults to a different folder -- it is the folder
> that I saved my last Excel file, which usually is a totally different folder.
>
> Is there a way for me to have SAVE AS default to the same folder that the
> current file is?
>
> Any ideas is greatly appreciated! This has been quite annoying.

--

Dave Peterson