vlookup question

VLOOKUP looks at the left-most column in a rectangle of data (generally 2 or more columns) for a specific item that you specify, then goes over to the right a specific number of columns (that you also specify) from that specific item and gives you the data from that cell. So, the function requires a lookup value (the specific item), the range (the rectangle), and the column index number (the number of columns over to the right). You can also specify whether you want it only to look for an exact value or whether you want it to find the closest value that's less than or equal to the value you specify (obviously, this would only work with numerical items).

In the range A1:B25, you would put a lookup table like this:

-1.2 Y
-1.1 X
-1 W
-0.9 V
-0.8 U
-0.7 T
-0.6 S
-0.5 R
-0.4 Q
-0.3 P
-0.2 O
-0.1 N
0 M
0.1 L
0.2 K
0.3 J
0.4 I
0.5 H
0.6 G
0.7 F
0.8 E
0.9 D
1 C
1.1 B
1.2 A

And, in E44, you would put this equation:
=VLOOKUP(C44,A$1:B$25,2,TRUE)

EDIT:
actually, I should have tested this first... the equation won't work for scores <-1.2, so you would need some kind of workaround; the first thing that comes to mind is using this equation instead:

=IF(C44<-1.2,"Y",VLOOKUP(C44,A$1:B$25,2,TRUE))

or you can use the orginal equation and add a top row to the lookup table like this (or replace -1000 with whatever the minimum possible score is)
-1000 Y
and the rest of your table would come after this
-1.2 Y
-1.1 X
etc...
change the range in your VLOOKUP to A$1:B$26

the solution given may work, but Rothmans has not specified the ranges. -1.15 will give an answer of Y above. and -1.3 will cause an error. Rothmans needs to be more explict with their question for the answers and in which range the boundary points fall eg

>1.2
>1.1 but <=1.2

But Vlookup will be the basis of the result. they have asked for an impossbile solution as 26 criteria are meant to be represented by 25 letters!

Regards

Dav

another option, which will totally avoid a lookup table:

=IF(ISBLANK(C44),"",IF(C44<-1.2,"Y",IF(C44>1.2,"A",MID("YXWVUTSRQPONMLKJIHGFEDCBA",INT(C44*10+13),1))))

note that this will, in effect, ignore digits beyond the first decimal place, so a score of 1.15 will be the same as 1.1, 1.11, 1.19, etc. (all will be 1.1). If you would prefer rounding, you can use this:

=IF(ISBLANK(C44),"",IF(C44<-1.2,"Y",IF(C44>1.2,"A",MID("YXWVUTSRQPONMLKJIHGFEDCBA",ROUND(C44*10+13,0),1))))

Here's another way

=IF(C44="","",CHAR(MEDIAN(65,89,77-ROUND(C44*10,0))))