Excel 2007 : Constructing a formula that counts distinct words in a single cell

Here is what I need. I need to be able to count text in a single cell without the duplicates being counted. For example a single cell may contain the following:

1, 2, 3, 4, 4, 5, 5

I already have the formula that will count all of the characters an trim the spaces and give me a result of 7.

I need a formula that will do the same thing, but not count the duplicates, giving me a result of 5.

Any help would be greatly appreciated! Thanks in advance!

April

Welcome to the forum,

Your post does not comply with Rule 1 of our Forum RULES. Your post title should accurately and concisely describe your problem, not your anticipated solution. Use terms appropriate to a Google search. Poor thread titles, like Please Help, Urgent, Need Help, Formula Problem, Code Problem, and Need Advice will be addressed according to the OP's experience in the forum: If you have less than 10 posts, expect (and respond to) a request to change your thread title. If you have 10 or more posts, expect your post to be locked, so you can start a new thread with an appropriate title.
To change a Title on your post, click EDIT then Go Advanced and change your title, if 2 days have passed ask a moderator to do it for you.

Try

=SUM(IF(LEN(A1)-LEN(SUBSTITUTE(A1,{1,2,3,4,5,6,7,8,9},"")),1))

confirmed with CTRL+SHIFT+ENTER not just ENTER...

change A1 to actual cell reference first.

If you only have single digits as per your example then this formula will count them

=COUNT(FIND({1,2,3,4,5,6,7,8,9,0},A1))

Indeed, a better alternative

I guess if you have 2 or 3 digit numbers too.. then you can use:

=COUNT(FIND(ROW(INDIRECT({"1:1000"}))-1,A1))

confimed with CTRL+SHIFT+ENTER...

Change 1000 if larger than 3-digit numbers can be found

Try:

=COUNT(FIND(ROW(INDIRECT({"1:32"})),Jan!G2))

Hold the CTRL and SHIFT keys down and then hit ENTER

Did you copy it exactly? I just copied/pasted back to my workbook to verify and it was okay.

Originally Posted by NBVC

Try:

=COUNT(FIND(ROW(INDIRECT({"1:32"})),Jan!G2))

Hold the CTRL and SHIFT keys down and then hit ENTER

That won't work here because it won't differentiate between a single 1 and a 1 in 11, 21 or 31, so for this data

6, 17, 25, 32

you'll get a count of 9 because it will count 1, 2, 3, 5, 6, 7, 17, 25 and 32

Assuming only numbers between 1 and 32 separated by comma+space with no extra characters at the start or end you could use this version

=COUNT(FIND(" "&ROW(INDIRECT("1:32"))&","," "&Jan!G2&","))

confirmed with CTRL+SHIFT+ENTER

or to avoid CSE

=SUMPRODUCT(ISNUMBER(FIND(" "&ROW(INDIRECT("1:32"))&","," "&Jan!G2&","))+0)

I obviously should have tested it better... not thinking

If you used the COUNT formula you must hold the CTRL and SHIFT keys down after you type or paste in the formula and then hit ENTER...

otherwise, use the SUMPRODUCT() version and just hit ENTER.