VLOOKUP to find values in text string???

You need code to do this:

Sub x()
    Dim rA          As Range
    Dim rB          As Range
    Dim cellA       As Range
    Dim cellB       As Range
    Dim sA          As String
    Dim sB          As String
    Dim iPos        As Long

    Set rA = Range("A1", Cells(Rows.Count, "A").End(xlUp))
    Set rB = Range("B1", Cells(Rows.Count, "B").End(xlUp))

    With rA.Font
        .Bold = False
        .Italic = False
        .Underline = False
        .ColorIndex = xlColorIndexAutomatic
    End With
        
    For Each cellA In rA
        If VarType(cellA.Value) = vbString Then
            sA = UCase(cellA.Value)

            For Each cellB In rB
                If VarType(cellB.Value) = vbString Then
                    sB = UCase(cellB.Value)
                    
                    iPos = 0
                    iPos = InStr(iPos + 1, sA, sB)
                    Do While iPos
                        With cellA.Characters(Start:=iPos, Length:=Len(cellB.Text)).Font
                            .Bold = True
                            .Italic = True
                            .Color = vbRed
                            .Underline = True
                        End With
                        iPos = InStr(iPos + 1, sA, sB)
                    Loop
                End If
            Next cellB
        End If
    Next cellA
End Sub

That's a completely different question for a completely different thread.