Novice query- copying between sheets

Are the columns of data having the same headers in all your sheets?

What is your data range? I mean what are the columns having the data? For e.g. A to K?

Do you want the copy paste to be triggered by a button?

Its not ideal to have it run automatically, as it will be tough to identify which rows have been copied and which not.
Instead, if you trigger it by a button, we can have the macro clean up the "everything" sheet and reload all the sheets' data into it.

What do you say?

Last question - do you need a column to state which sheet the data was copied from?

Oops another question - can you give me the headers that need to go into the "everything" sheet?

I see you have posted some code for a similar thread Arlette:

Option Explicit

Sub create_format()
Dim lrow As Long, i As Long, a As Long
Dim fpath As String, xinput As String

a = 1
fpath = "D:\Test\"
Workbooks.Open (fpath & "b.xls")
xinput = InputBox("Please enter the value for x")
With ThisWorkbook.Worksheets("Sheet1")
    lrow = .Range("A" & .Rows.Count).End(xlUp).Row
    For i = 1 To lrow
        If .Range("B" & i).Value = xinput Then
            Workbooks("b.xls").Worksheets("Sheet1").Range("A" & a).Value = .Range("A" & i).Value
            a = a + 1
        End If
    Next i
End With

End Sub

Is this something like the approach I should be using?

No, this code is only to copy from one sheet to another sheet in a new workbook.

I will give you the code shortly.

Should the data be consolidated from column C onwards or should it start from A?

Try this code

Option Explicit

Sub cons_sheets()
Dim ws As Worksheet
Dim lrow As Long, lrow1 As Long

Application.ScreenUpdating = False

If Not Evaluate("ISREF(Summary!A1)") Then
    Worksheets.Add(after:=Worksheets(Worksheets.Count)).Name = "Summary"
Else
    Worksheets("Summary").Cells.ClearContents
End If
Worksheets("Summary").Range("C1:I1") = Split("Date,Description, Action,Operative,Hours,Complete,Sheet", ",")

For Each ws In ThisWorkbook.Worksheets
    If ws.Name <> "Summary" Then
        lrow = ws.Range("C" & Rows.Count).End(xlUp).Row
        ws.Range("C7:H" & lrow).Copy Worksheets("Summary").Range("C" & Rows.Count).End(xlUp).Offset(1, 0)
        lrow = Worksheets("Summary").Range("I" & Rows.Count).End(xlUp).Row
        lrow1 = Worksheets("Summary").Range("C" & Rows.Count).End(xlUp).Row
        Worksheets("Summary").Range("I" & lrow + 1 & ":I" & lrow1).Value = ws.Name
    End If
Next ws

Application.ScreenUpdating = True

End Sub

Copy the Excel VBA code
Select the workbook in which you want to store the Excel VBA code
Hold the Alt key, and press the F11 key, to open the Visual Basic Editor
Choose Insert | Module
Where the cursor is flashing, choose Edit | Paste

To run the Excel VBA code:
Choose Tools | Macro | Macros
Select a macro in the list, and click the Run button

Am glad it worked.

a. I have changed the code to start from row 7.

b. You can insert a button on your sheet. Right click on it and say Assign macro and assign the macro cons_sheets. Thats it.

To insert the button - Right click on your toolbar at the top of your screen and select the "Visual Basic" menu. You will find a command button there if you click on the control toolbox.

If you click on the button, you will see some text appearing in the formula bar. Remove that text and then you should be able to see the assign macro on the right click.