Head Tail combinations

[vbax]

Hi,

I need some help in coming up with the combination of coin tossing. When we throw a coin, we can have a two combinations, a Head and tail. so it can be HT. When we toss two coin , the combination HH,TH,HT,TT. When do toss three coins then it will be HHH, THH, HTH, TTH, HHT, THT, HTT,TTT.

I would like to get a VBA program in excel which can generate the possible combinations of coins tossing, i need the output in a excel which will accept number of coins and the possible combinations. Its the program which can show the output of 2 to the power of n.

can some one pls help.

thanks
vbax

[mikerickson]

I think this might do what you want.

Sub test()
    Dim HowManyCoins As Long
    Dim outArray() As String, outRange As Range
    Dim i As Long, Size As Long
    Set outRange = Sheet1.Range("q1")
    
    HowManyCoins = Application.InputBox("How many coins?", Default:=2, Type:=1)
    If HowManyCoins < 1 Then Exit Sub: Rem cancel pressed
    Size = 2 ^ (HowManyCoins)
    ReDim outArray(1 To Size, 1 To 1)
    
    For i = 1 To Size
        outArray(i, 1) = WorksheetFunction.Dec2Bin(i - 1, HowManyCoins)
        
        outArray(i, 1) = Replace(Replace(outArray(i, 1), "0", "H"), "1", "T")
    Next i
    
    With outRange.Resize(Size, 1)
        .EntireColumn.ClearContents
        .Value = outArray
    End With
End Sub

[kalak]

just in case you want more than 9

Sub H_and_T()
Dim list(), i&, x&, j&, c&, k&, n&
n = InputBox("How many?")
ReDim list(1 To 2 ^ n, 1 To 1)

For i = 1 To n
    x = 2 ^ (n - i)
    For j = 1 To 2 ^ n Step x
        For k = j To j + x - 1
            list(k, 1) = list(k, 1) & Chr(72 + 12 * c)
        Next k
        c = c + 1: If c = 2 Then c = 0
    Next j
Next i

Cells(1, "c").Resize(2 ^ n, 1) = list
End Sub