UserForm Change Event

For a Change event, you could use a class module to trap the event for all the relevant textboxes. If you assign the address of the cell to change to the Tag property of each textbox, the code would be fairly straight forward.

Open the VBEditor and insert a class module. Use the Properties window to change its name to clsAnyTextBox
Then put this code in that class module.

' in clsAnyTextBox module

Public WithEvents TextBox As MSForms.TextBox

Event Change()

Private Sub TextBox_Change()
    Set TextBox.Parent.anyTextBox = Me
    RaiseEvent Change
End Sub

Then you can put code like this in your userform's code module

' in userform code module

Public WithEvents anyTextBox As clsAnyTextBox
Dim myTextBoxes As Collection

Private Sub UserForm_Initialize()
    Dim oneTextbox As Variant
    Dim oneAny As clsAnyTextBox
    Dim I As Long
    Set myTextBoxes = New Collection
    
    Rem matches each textbox of interest to its linked cell
   For I = 0 to 2
         Array(Me.TextBox1, Me.TextBox2, Me.TextBox3)(I) = Array(Range("A1"),Range("B2"),Range("C3"))(I).Address(,,,true)
    Next i

    
    Rem for each textbox of interest
    '   creates a clsAnyTextBox object,
    '   assigns that text box to that custom object,
    '   and puts the custom object in a collection
  For Each oneTextbox In Array(Me.TextBox1, Me.TextBox2, Me.TextBox3)
        Set oneAny = New clsAnyTextBox
        Set oneAny.TextBox = oneTextbox
        myTextBoxes.Add Item:=oneAny, Key:=oneTextbox.Name
    Next oneTextbox
    
    Set oneAny = Nothing
End Sub

Private Sub anyTextBox_Change()
    With anyTextBox.TextBox
        msgBox .Name & " has changed."
        Range(.Tag) = .Text
    End With
End Sub

Your loop through textboxes (in the Initialize event) might be different.

Note that the userform variable anyTextBox is a clsAnyTextBox object. To refer to the textbox itself, use anyTextBox.TextBox

Untested but something like this:
1. Add a new Class module to your project, change its name to CTextboxHandler, then paste this code in:

Option Explicit

Private WithEvents m_tb As MSForms.Textbox
Private m_rngLink As Excel.Range
Public Property Set Textbox(tb As MSForms.Textbox)
    Set m_tb = tb
End Property
Public Property Get Textbox() As MSForms.Textbox
    Set Textbox = m_tb
End Property
Public Property Set CellLink(rng As Excel.Range)
    Set m_rngLink = rng
End Property
Private Sub m_tb_Change()
    m_rngLink.Value = m_tb.Value
End Sub

Now add this to your Userform code:
at the top of the code module before any routines:

Dim colTBs as Collection

Now in the Userform_Initialize code you need:

Private Sub Userform_Initialize()
Dim oHandler as CTextboxHandler
Dim x As Long

set colTBs = New Collection

For x = 1 To 15
   Set oHandler = New CTextboxHandler 
   set oHandler.Textbox = Me.Controls("txtPTno" & x)
   Set oHandler.CellLink = Sheets("Personal Tax").Range("C" & x).Offset(x - 2)
   colTBs.add oHandler
Next x
End Sub

Can you post it?

Never mind - the problem is here:

Set oHandler.CellLink = Sheets("Personal Tax").Range("C" & x).Offset(x - 2)

When x is 1 you're trying to refer to cell C0 which doesn't exist. You need to adjust the logic to whatever fits your layout.