Copy same range in many excel files and paste into a main file

Please, I need a little help.
I want to copy a range from many excel files and paste into another one.

All the files (with the ranges to be copied) are closed inside a folder, with sequential names .
The file that will receive the ranges ("Boxx") is in another folder.

I want to copy the range "B1:S5" and paste in "B1"(in "Boxx").
Then, the next ranges should be pasted sequentially in B6, B11, B16, etc.

The closest VBA code I've found and modified is here:

Sub Themissedline()

Dim lCount As Long
Dim wbResults As Workbook
Dim wbCodeBook As Workbook

Application.ScreenUpdating = False
Application.DisplayAlerts = False
Application.EnableEvents = False

On Error Resume Next
    Set wbCodeBook = ThisWorkbook
        With Application.FileSearch
        .NewSearch
        'Change path to suit
        .LookIn = "E:\DOWNLOADS\IIII"
        .FileType = msoFileTypeExcelWorkbooks
        'Optional filter with wildcard
        '.Filename = "*AAAA.xls"
        If .Execute > 0 Then 'Workbooks in folder
        For lCount = 1 To .FoundFiles.Count 'Loop through all
        'Open Workbook x and Set a Workbook variable to it
        Set wbResults = Workbooks.Open(Filename:=.FoundFiles(lCount), UpdateLinks:=0)


wbResults.Worksheets("Plan1").Range("B1:S5").Copy
wbCodeBook.Worksheets("Plan1").Range("B1" & Rows.Count).End(xlUp).Offset(1).PasteSpecial xlPasteValues
Application.CutCopyMode = False
                        

                        wbResults.Close SaveChanges:=False
                    Next lCount
                End If
        End With
On Error GoTo 0
Application.ScreenUpdating = True
Application.DisplayAlerts = True
Application.EnableEvents = True

End Sub

What's the missed line??

I modified some code I already had for something similar.

Sub LoopAllExcelFilesInFolder()
'PURPOSE: To loop through all Excel files in a user specified folder and perform a set task on them
'==============================================
'Declare Variables
'==============================================
    Dim wb As Workbook
    Dim myPath As String
    Dim myFile As String
    Dim myExtension As String
    Dim FldrPicker As FileDialog
    Dim LastRow As Long
    Dim SourceRng As String

'==============================================
'Optimize Macro Speed
'==============================================
  Application.ScreenUpdating = False
  Application.EnableEvents = False
  Application.Calculation = xlCalculationManual

'==============================================
'Find Folder and Define Variables
'==============================================
    SourceRng = "B1:S5" 'Used to define Source Range
    Set FldrPicker = Application.FileDialog(msoFileDialogFolderPicker)

    With FldrPicker
      .Title = "Select A Target Folder"
      .AllowMultiSelect = False
        If .Show <> -1 Then GoTo NextCode
        myPath = .SelectedItems(1) & "\"
    End With

'In Case of Cancel
NextCode:
    myPath = myPath
        If myPath = "" Then
        'Turn these things back on then exit
            Application.ScreenUpdating = True
            Application.EnableEvents = True
            Application.Calculation = xlCalculationAutomatic
                MsgBox "Nothing Was Selected. Macro will End."
               Exit Sub
        End If
  
    'Target File Extension (must include wildcard "*")
    myExtension = "*.xls"
    'Target Path with Ending Extention
    myFile = Dir(myPath & myExtension)
    FileCounter = 1

'===================================================================
'Clear Data tab before begining
'===================================================================
    ThisWorkbook.Sheets("Data").Range("A1:S1048576").Clear 'Set this range to whatever you need
        'This clears whatever range you need to
        'I assumed you want to keep Row 1 to keep the headers
    LastRow = ThisWorkbook.Worksheets("Data").Cells(Rows.Count, 2).End(xlUp).Row 'Calculates the first Empty row on the data tab for 2nd column

'===================================================================
'This isnt Necessary, only to use the statusbar to indicate how far along you are
'===================================================================
    Do While myFile <> ""
           FileCount = FileCount + 1
            myFile = Dir()
        Loop
    myFile = Dir(myPath) ' Resets this to the first file in the folder instead of the last

'==============================================
'Loop through each Excel file in folder
'==============================================
  Do While myFile <> ""
    If myFile <> ThisWorkbook.Name Then
        Application.StatusBar = "Importing File [" & FileCounter & " of " & FileCount & "] : " & myFile
        
        'Set variable equal to opened workbook
        Set wb = Workbooks.Open(Filename:=myPath & myFile)
        
        'Append data from workbook
        ThisWorkbook.Worksheets("Data").Range("B" & LastRow & ":S" & LastRow + 4).Value2 = wb.Sheets("Plan1").Range(SourceRng).Value2
        
        'Recalc last row in Thisworkbook
        LastRow = ThisWorkbook.Worksheets("Data").Cells(Rows.Count, 2).End(xlUp).Row + 1
        
        'Close Workbook without Saving
        wb.Close SaveChanges:=False
    
            FileCounter = FileCounter + 1
    
    End If
    
    'Get next file name
      myFile = Dir
  Loop
'==============================================
'Message Box when tasks are completed
'==============================================
  MsgBox "Imported " & FileCount & " Files Succesfully"

'==============================================
'Reset Macro Optimization Settings
'==============================================
  Application.StatusBar = False
  Application.ScreenUpdating = True
  Application.EnableEvents = True
  Application.Calculation = xlCalculationAutomatic
  
End Sub