Scraping data from website

does this still need your help?

I was able to figure out the solution to the problems that I was having. The code is working perfectly the way that I intended the code to. Thank you

Glad to hear!
In that case, please mark this thread as solved - it would also be good for future reference of people if you can include your working code, in case someone might be looking for it.

Thanks!

This is the finally working code where I am able to scrape the data in the way I had initially intended on doing so.

[CODE]
'Macro to query Daily Activity Search for DFB Counties
'Run Monday to pull data from Friday


Sub queryActivityDailyMforFWorking()
On Error GoTo Err_queryActivityDailyMforFWorking

Const RowsPerPage As Byte = 20
Const DeleteHeader As Boolean = True

Dim nextrow As Integer, maxrow As Integer, i As Integer
Dim dates As Date

dates = Date - 3

Application.ScreenUpdating = False
Application.DisplayStatusBar = True

nextrow = 1
For i = 1 To 50
Application.StatusBar = "Processing Page " & i
With ActiveSheet.QueryTables.Add(Connection:= _
"URL;https://www.myfloridalicense.com/delinquency_results.asp?SID=&page=" & i & "&county_1=16&county_1=21&county_1=23&county_1=32&county_1=36&county_1=41&county_1=46&county_1=53&county_1=54&county_1=57&county_1=60&county_1=66&status=R&send_date=" & Format(dates, "m/d/yyyy") & "&search_1.x=1", _
Destination:=Range("A" & nextrow))
'.Name = _
"2015&search_1.x=40&search_1.y=11&date=on&county_1=AL&lic_num_del=&lic_num_rep=&status=NS&biz_name=&owner_name="
.FieldNames = False
.RowNumbers = False
.FillAdjacentFormulas = False
.PreserveFormatting = True
.RefreshOnFileOpen = False
.BackgroundQuery = True
.RefreshStyle = xlInsertDeleteCells
.SavePassword = False
.SaveData = True
.AdjustColumnWidth = True
.RefreshPeriod = 0
.WebSelectionType = xlSpecifiedTables
.WebFormatting = xlWebFormattingNone
.WebTables = "10"
.WebPreFormattedTextToColumns = True
.WebConsecutiveDelimitersAsOne = True
.WebSingleBlockTextImport = False
.WebDisableDateRecognition = False
.WebDisableRedirections = False
.Refresh BackgroundQuery:=False
End With

' Delete the header as required
If DeleteHeader And i > 1 And ActiveSheet.Cells(nextrow, 1).Value = "License" Then ActiveSheet.Cells(nextrow, 1).EntireRow.Delete

' Find the bottom row
maxrow = Application.WorksheetFunction.Max(ActiveSheet.Cells(Rows.Count, 1).End(xlUp).row, ActiveSheet.Cells(Rows.Count, 2).End(xlUp).row)
' Stop scraping if a full page wasn't returned
If (maxrow - nextrow) < (RowsPerPage - IIf(DeleteHeader, 1, 0)) Then
Exit For
' Otherwise set the row for the next page of data
Else
nextrow = maxrow + 1
End If
Next i

Application.StatusBar = "Formatting data"

'autofit columns
ActiveSheet.Columns.EntireColumn.AutoFit

'check for filter, if not then turn on filter
ActiveSheet.AutoFilterMode = False
If Not ActiveSheet.AutoFilterMode Then ActiveSheet.Range("A:G").AutoFilter

'Align text left
With ActiveSheet.Cells
.HorizontalAlignment = xlLeft
.VerticalAlignment = xlBottom
.WrapText = False
.Orientation = 0
.AddIndent = False
.IndentLevel = 0
.ShrinkToFit = False
.ReadingOrder = xlContext
.MergeCells = False
End With

Exit_queryActivityDailyMforFWorking:
Application.StatusBar = False
Application.ScreenUpdating = True
Exit Sub

Err_queryActivityDailyMforFWorking:
MsgBox Err.Description, vbCritical + vbOKOnly, Err.Number & " - Web Scraping Error"
Resume Exit_queryActivityDailyMforFWorking

End Sub
[CODE]