"Replace:=False" Not Working with .Select Function

I have the following code that used to (Excel 2003) select any sheet with a tab color that matches the fill color of a certain cell (TabColor in the code).

Private Sub PrintTabs_Click()

  Dim wks As Worksheet
  Dim TabColor As Long
  Dim PrintSheets As String
 
TabColor = Sheets("_Options_").Range("TabColor").Interior.Color 'Tab Color to Print (Points to a cell with a user defined color)
 
    For Each wks In Worksheets
          If wks.Tab.Color = TabColor Then
            wks.Select False
          End If
    Next wks
  
   ActiveWindow.SelectedSheets.PrintPreview
    
End Sub

Now (Excel 2013), it does not select anything at all, unless I remove the "False" after the .Select. I also tried "Replace:=False" with the same results. When anything regarding the "False" is removed, the final result will be that the last sheet that meets the criteria will be selected. I would like all sheets that match the color to be selected.

Any help would be appreciated.

Thank you,

Mark

Hi,

You might use an array of sheet names instead.

Private Sub PrintTabs_Click()

    Dim wks                   As Worksheet
    Dim TabColor              As Long
    Dim PrintSheets           As String
    Dim asSheets()            As String
    Dim i                     As Long

    i = 0
    TabColor = Sheets("_Options_").Range("TabColor").Interior.Color    'Tab Color to Print (Points to a cell with a user defined color)
    ReDim asSheets(1 To Sheets.Count)
    For Each wks In Worksheets
        If wks.Tab.Color = TabColor Then
            i = i + 1
            asSheets(i) = wks.Name
        End If
    Next wks
    ReDim Preserve asSheets(1 To i)
    Sheets(asSheets).Select
    ActiveWindow.SelectedSheets.PrintPreview

End Sub

You're most welcome.