How to open an existing Word document from Excel

Try.

    With CreateObject("word.Application")
        .documents.Open "C:\Documents and Settings\mydoc.doc" 'change path and name to suit
        .Visible = True
    End With

I admit I have not tested the following but I believe it should fix the syntax issues

Sub Open_Word_Document() 'Open an existing Word Document from Excel
Dim objWord As Object
Dim objDoc As Object

Set objWord = CreateObject("Word.Application")

objWord.Visible = True 'Change the directory path and file name to the location
Set objDoc = objWord.Documents.Open("U:\EVERYBODY!\Antalis\AntalisBarCode.docx")  'of the document you want to open from Excel  b

MakeLabels objDoc
End Sub
   
Sub MakeLabels(MMDocument As Object)
    '
    ' Macro2 Macro this code is at heart a macro
    '
    
    Const wdMailingLabels As Long = 1
    Const wdOpenFormatAuto As Long = 0
    Const wdMergeSubTypeAccess = 1
    Const wdAlignParagraphCenter = 1
    Const wdSendToPrinter As Long = 1
    Const wdDefaultFirstRecord As Long = 1
    Const wdDefaultLastRecord As Long = -16
    
    With MMDocument
        .MailMerge.MainDocumentType = wdMailingLabels
        .MailMerge.OpenDataSource Name:= _
            "U:\EVERYBODY!\Antalis\Antalis_BarCodes.xlsm", ConfirmConversions:=False, _
            ReadOnly:=False, LinkToSource:=True, AddToRecentFiles:=False, _
            PasswordDocument:="", PasswordTemplate:="", WritePasswordDocument:="", _
            WritePasswordTemplate:="", Revert:=False, Format:=wdOpenFormatAuto, _
            Connection:= _
            "Provider=Microsoft.ACE.OLEDB.12.0;User ID=Admin;Data Source=U:\EVERYBODY!\Antalis\Antalis_BarCodes.xlsm;Mode=Read;" & _
            "Extended Properties=""HDR=YES;IMEX=1;"";Jet OLEDB:System database="""";Jet OLEDB:Registry Path="""";Jet OLEDB:Engine Type=37;Jet OLEDB:Database Loc", _
            SQLStatement:="SELECT * FROM `Sheet1$`", SQLStatement1:="", SubType:=wdMergeSubTypeAccess
    
        With .Application.Selection
            .ParagraphFormat.Alignment = wdAlignParagraphCenter
            MMDocument.MailMerge.Fields.Add Range:=.Range, Name:="CODE"
            .Font.Name = "EAN-13"
            .Font.Size = 72
        End With
        With .MailMerge
            .Destination = wdSendToPrinter
            .SuppressBlankLines = True
            With .DataSource
                .FirstRecord = wdDefaultFirstRecord
                .LastRecord = wdDefaultLastRecord
            End With
            .Execute Pause:=False
        End With
    End With
End Sub

Hi John,

Do you have a reference set to the Word library? If you do not, you cannot make use of Word's native constants without declaring them explicitly. I would guess you do not since your code is late bound?

There are several other issues with your object references that I will endeavour to fix shortly.

In my experience dynamic ranges do not work with queries, although this may not be true if the container workbook is already opened.

You can use a WHERE clause to only return records where a field is not blank

SELECT * FROM `Sheet1$` WHERE NOT [field name] Is Null

It would be written as [CODE] without the quote marks.

Anything beginning with 'wd' is a built in constant from the Word application. You should not try to change that- it simply means the merge should use all the records available.

Since you already have a document for the mailmerge, why are you using this code:

        With .Application.Selection
            .ParagraphFormat.Alignment = wdAlignParagraphCenter
            MMDocument.MailMerge.Fields.Add Range:=.Range, Name:="CODE"
            .Font.Name = "EAN-13"
            .Font.Size = 72
        End With

Whatever fields you need should already be there in your document, all appropriately formatted. Moreover, since you're apparently trying to do a label merge, simply adding this field to the document is unlikely to produce the desired results - at best your field would be added to a single label and the rest of the sheet would be wasted.

The Constant declarations are not the problem, neither was the lack of a reference to Word. Your code is written for use with late binding, which is why the reference to Word isn't required but the Constant declarations are. Declaring Constants in this way allows your code to be read as if it were using early binding (for which a reference to Word would be required). Using late binding can be an advantage if your code is to be used with different Office versions.

If you want to print a particular range of labels, you need code to solicit the start and/or end numbers. For example:

            With .DataSource
                .FirstRecord = InputBox("What is the first record to output?", "First record input", wdDefaultFirstRecord)
                .LastRecord = InputBox("What is the last record to output?", "Last record input", .RecordCount)
                If .FirstRecord < 1 Then .FirstRecord = wdDefaultFirstRecord
                If .FirstRecord > .RecordCount Then .FirstRecord = .RecordCount
                If .LastRecord > .RecordCount Then .LastRecord = wdDefaultLastRecord
                If .LastRecord < .FirstRecord Then .LastRecord = .FirstRecord
            End With