Scripting Dictionary (working as vlookup) and add calculated columns

Hi,
im working on the project :
I got the code for making script dictionary working as vlookup from another spredsheet

Sub slownik_dzialajacy_xcol()

Const delim As String = "|"
Dim str As Variant
Dim a, i, u As Long
Dim dic As Object
Set dic = CreateObject("Scripting.Dictionary")
   With Application
           .ScreenUpdating = False
           .EnableEvents = False
    End With
    
    With Sheets("Arkusz1")
        
        i = .Range("A" & .Rows.Count).End(xlUp).Row
        u = .Cells(2 & .Columns.Count).End(xlToLeft).Column
        a = .Range("A1:BU" & i).Value
        
        For i = LBound(a, 1) To UBound(a, 1)
            dic(a(i, 1)) = a(i, 2) & delim & a(i, 3) & delim & a(i, 4) 
        
    End With

    With Sheets("Arkusz2")
    
        For i = 2 To .Range("A" & .Rows.Count).End(xlUp).Row
            str = Split(dic(.Range("A" & i).Value), delim)
            .Range("B" & i).Resize(, 4).Value = str
            Erase str
        Next i
        
    End With

Set dic = Nothing
Erase a
   With Application
           .ScreenUpdating = True
           .EnableEvents = True
    End With
    
End Sub

This part of code making just straight vlookup based on a key from range A:A in sheet2 (and look it up in sheet1), and then put them in sheet2.
What i need to do is after this copying the dictionary would look in the source for reference and for example add values from Column O and Column P from sheet1 and put them next to vlookuped values in sheet2.

Best Regards,
Mumsy

"Next"?

Sub slownik_dzialajacy_xcol()

Const delim As String = "|"
Dim str As Variant
Dim a, i, u As Long
Dim dic As Object,w
Set dic = CreateObject("Scripting.Dictionary")
   With Application
           .ScreenUpdating = False
           .EnableEvents = False
    End With
    
    With Sheets("Arkusz1")
        
        i = .Range("A" & .Rows.Count).End(xlUp).Row
        u = .Cells(2 & .Columns.Count).End(xlToLeft).Column
        a = .Range("A1:BU" & i).Value
    end with
        
        For i = LBound(a, 1) To UBound(a, 1)
            if not dic.exist(a(i, 1)) then
                dic(a(i,1))= array(a(i, 2),a(i, 3),a(i, 4),a(i,15),a(i,16))             
            else
                w=dic(a(i,1)):w(3)=w(3) + a(i,15):w(4)=w(4) + a(i,16)
                dic(a(i,1)) = w
            end if
        next

    With Sheets("Arkusz2")
    
        For i = 2 To .Range("A" & .Rows.Count).End(xlUp).Row
            if dic.exists(.range("a" & i).value) then
                .Range("B" & i).Resize(, 4).Value = dic(.range("a" & i).value)
            end if
        Next i
        
    End With

Set dic = Nothing
Erase a
   With Application
           .ScreenUpdating = True
           .EnableEvents = True
    End With
    
End Sub

Thx for answer, unfortunately i got object doesn't support this property or method error on line

if not dic.exist(a(i, 1)) then
                dic(a(i,1))= array(a(i, 2),a(i, 3),a(i, 4),a(i,15),a(i,16))

I'm posting example workbook to get lil more visual about it:

If somethings unclear there pls ask
BR,

Sorry that was a typo, should be "exists"

You will need to adjust the array as per your real data layouts.

Sub test()
    Dim a, i As Long, ii As Long, w, dic As Object
    Set dic = CreateObject("Scripting.Dictionary")
    a = Sheets("SOURCE SHEET").Cells(1).CurrentRegion.Value
    For i = 2 To UBound(a, 1)
        dic(a(i, 1)) = Array(a(i, 2), a(i, 3), a(i, 4), a(i, 5) + a(i, 6), a(i, 5) + a(i, 6))
    Next
    a = Sheets("SOURCE SHEET EXPENSES").Cells(1).CurrentRegion.Value
    For i = 2 To UBound(a, 1)
        If (dic.exists(a(i, 1))) * (a(i, 4) > 500) Then
            w = dic(a(i, 1)): w(4) = w(4) - a(i, 4)
            dic(a(i, 1)) = w
        End If
    Next
    With Sheets("OUTPUT SHEET").Cells(1).CurrentRegion
        .Offset(1, 1).ClearContents
        a = .Value
        For i = 2 To UBound(a, 1)
            If dic.exists(a(i, 1)) Then
                For ii = 2 To UBound(a, 2)
                    a(i, ii) = dic(a(i, 1))(ii - 2)
                Next
            End If
        Next
        .Value = a
    End With
End Sub

You could use Val function to convert it as Double.
i.e

For i = 2 To UBound(a, 1)
        dic(a(i, 1)) = Array(a(i, 2), a(i, 3), a(i, 4), a(i, 6), Val(a(i, 9)) + Val(a(i, 10)))
Next

And so is the rest...