Validate Data between two workbooks

Hello,

I am looking to see if there is a way in which I can validate that the totals from my one workbook (Lakers Stats By Season) to make sure that they match with a player's totals in the workbook 1989-90 Los Angeles Lakers. The worksheet to follow within the 1989-90 Los Angeles Lakers workbook is named 1989-90 Stats. I have attached both workbooks and I have all of the headers that would need to be validated from the column that has G as the header all the way to PTS based off the player name.

I will be wanting to do this for other workbooks that are not attached and validating the totals data using the workbook Lakers Stats By Season, I have named each sheet after the workbook that I will be working with.

Let me know if this is possible and Thank You in advance for your help.

Hi kingsdime29x- Here's a macro to handle your validation. It opens your 'XXX...Lakers' WBs one at a time, runs a comparison, and closes them. I've included instructions in the attached workbook. Let me know if you have any problems. -Lee
ps. If this does the trick, please mark the thread as SOLVED (Thread Tools, up top)... and perhaps click the Add Reputation star at the bottom of this post. Thanks!

for the browsers:

Sub CompareStats()

    '''''''''''''''''''    LLN 2017-04-21    '''''''''''''''''''''''
    
    Dim rw As Long, indx As Long, cnt As Long, errRow As Long, errCnt As Long
    Dim player As String, statsLAL As Range, statsBS As Range, found As Range
    Dim folderpath As String, WBLAL As String, WS As Worksheet
    
    Application.ScreenUpdating = False
    ThisWorkbook.Activate
    folderpath = Application.ThisWorkbook.Path & "\"

    For cnt = 1 To ThisWorkbook.Worksheets.Count
        Set WS = Worksheets(cnt)
        WBLAL = WS.Name & ".xlsx"
        Workbooks.Open folderpath & WBLAL
        WS.Activate
        With Workbooks(WBLAL).Worksheets(Left(WS.Name, 7) & " Stats") '1989-90 Stats

            errRow = Cells(2, 2).End(xlDown).Row + 2
            Range("A1:P1").Copy Destination:=Cells(errRow, 1)

            For rw = 2 To Cells(2, 2).End(xlDown).Row
                player = Cells(rw, 2).Value
                Set found = .Range("B:B").Find(player)

                If found Is Nothing Then
                    errRow = errRow + 1
                    errCnt = errCnt + 1
                    Cells(errRow, 2) = player & " NOT FOUND"

                Else
                    Set statsBS = Range("C1:P1").Offset(rw - 1)
                    Set statsLAL = .Range("D1:Q1").Offset(found.Offset(, 1).End(xlDown).Row - 1)

                    For indx = 1 To 14

                        If statsBS.Cells(1, indx).Value <> statsLAL.Cells(1, indx).Value Then
                            errRow = errRow + 1
                            errCnt = errCnt + 1
                            Cells(errRow, 2).Value = player
                            Cells(errRow, indx + 2).Value = statsLAL.Cells(1, indx).Value

                        End If
                    Next
                End If
            Next
        End With
        Workbooks(WBLAL).Close SaveChanges:=False
    Next
    
    Application.ScreenUpdating = True
    Beep
    MsgBox "All done. " & errCnt & " errors were found.", , "CompareStats macro"

End Sub

This is perfect! Thank you so much for your help.

My pleasure. Did you turn up many errors? If so, I could easily adjust the macro to change the 'By Season' data to match the Season Books.

Very few errors occurred and is working exactly as I would like. Thank you again for you help with this.