How to order according to comma and bracket?

Will the bracket set always stay with the preceding letter; "c" in your example?

Can there be more than one bracket set?

Here is one way.

Sub Test()

    Dim Text As String
    Dim startBracket As Long
    Dim endBracket As Long
    Dim index As Long
    Dim useChr As String
    Dim delimiter As String
    
    Text = ActiveCell.Text
    delimiter = ","
    
    useChr = ""
    For index = 128 To 255
        If InStr(Text, Chr(index)) = 0 Then
            useChr = Chr(index)
            Exit For
        End If
    Next
    
    If Len(useChr) = 0 Then
        MsgBox "Can not find unique temporary character. Text not sorted", vbExclamation
        Exit Sub
    End If
    
    endBracket = 1
    startBracket = InStr(endBracket, Text, "(")
    Do While startBracket > 0
        endBracket = InStr(startBracket, Text, ")")
        Mid(Text, startBracket + 1, endBracket - startBracket - 1) = Replace(SortText(Mid(Text, startBracket + 1, endBracket - startBracket - 1), delimiter, xlAscending, vbTextCompare), delimiter, useChr)
        startBracket = InStr(endBracket, Text, "(")
    Loop
    
    Text = Replace(SortText(Text, delimiter, xlAscending, vbTextCompare), useChr, delimiter)
    ActiveCell.Offset(0, 1) = Text
    
End Sub

Function SortText(Text As String, Optional delimiter As String = ",", Optional SortOrder As XlSortOrder, Optional CompareMethod As VbCompareMethod = VbCompareMethod.vbBinaryCompare) As String
   
    Dim items As Variant
    Dim tempItem As Variant
    Dim returnValue As String
    Dim outerIndex As Long
    Dim innerIndex As Long
    Dim lowerArraySize As Long
    Dim upperArraySize As Long
    Dim arrayStep As Long

    items = Split(Text, delimiter)
    If SortOrder = xlAscending Then
        lowerArraySize = LBound(items)
        upperArraySize = UBound(items)
        arrayStep = 1
    Else
        lowerArraySize = UBound(items)
        upperArraySize = LBound(items)
        arrayStep = -1
    End If
    
    For outerIndex = lowerArraySize To upperArraySize Step arrayStep
        For innerIndex = outerIndex To upperArraySize Step arrayStep
            If StrComp(items(innerIndex), items(outerIndex), CompareMethod) < 0 Then
                tempItem = items(outerIndex)
                items(outerIndex) = items(innerIndex)
                items(innerIndex) = tempItem
            End If
        Next
    Next

    returnValue = Join(items, delimiter)
    SortText = returnValue
    
End Function

In your examples you are not doing a case sensitive check. The function has parameters to handle sort order and type of comparison.

Try this code

Sub SplitAndJoin()

Dim IpStr As String
Dim BktNos As Long, Bkt As Long, BktRem As Long
Dim TA As Long, TB As Long

IpStr = Range("A3")

BktNos = Len(IpStr) - Len(Replace(IpStr, "(", ""))
ReDim Str(BktNos) As String

For Bkt = 1 To BktNos

    If InStr(1, IpStr, "(") > 0 Then
    Str(Bkt) = Mid(Left(IpStr, InStr(1, IpStr, ")") - 1), InStr(1, IpStr, "(") + 1)
    IpStr = Replace(IpStr, "(" & Str(Bkt) & ")", "ZZZ" & Bkt)
    
    M = Split(Str(Bkt), ",")
            For TA = 0 To UBound(M) - 1
                For TB = TA + 1 To UBound(M)
                
                If UCase(M(TA)) > UCase(M(TB)) Then
                temp = M(TA)
                M(TA) = M(TB)
                M(TB) = temp
                temp = ""
                End If
                
                Next TB
            Next TA
    Str(Bkt) = "(" & Join(M, ",") & ")"
    End If

Next Bkt

    M = Split(IpStr, ",")
            For TA = 0 To UBound(M) - 1
                For TB = TA + 1 To UBound(M)
                
                If UCase(M(TA)) > UCase(M(TB)) Then
                temp = M(TA)
                M(TA) = M(TB)
                M(TB) = temp
                temp = ""
                End If
                
                Next TB
            Next TA
    IpStr = Join(M, ",")

For BktRem = 1 To BktNos

IpStr = Replace(IpStr, "ZZZ" & BktRem, Str(BktRem))

Next BktRem

Range("B3") = IpStr

End Sub