MACRO for Deleting rows based on a cell value

How about:

Sub del_row()

Dim ws As Worksheet
Dim lr As Long

Set ws = ThisWorkbook.Worksheets("Sheet1") 'change sheet name as needed
lr = ws.Range("A" & Rows.Count).End(xlUp).Row 'last row with data, using column A, change if needed
ws.Range("AB1:AB" & lr).AutoFilter field:=1, Criteria1:="DELETE ROW"
ws.Range("AB2:AB" & lr).SpecialCells(xlCellTypeVisible).EntireRow.Delete
ws.AutoFilterMode = False

End Sub

I am not sure what I am doing wrong, this is how I have the macro into VBA

Sub del_row()

Dim ws As Worksheet
Dim lr As Long

Sheets("B291-Inventory Report by Locati").Select
lr = ws.Range("A" & Rows.Count).End(xlUp).Row
ws.Range("AB1:AB" & lr).AutoFilter field:=1, Criteria1:="DELETE ROW"
ws.Range("AB2:AB" & lr).SpecialCells(xlCellTypeVisible).EntireRow.Delete
ws.AutoFilterMode = False

End Sub

Or another option...

Sub FilterDelete()
    With Range("AB1", Range("AB" & Rows.Count).End(xlUp))
        .AutoFilter Field:=1, Criteria1:="DELETE ROW"
        .Offset(1).EntireRow.Delete
        .AutoFilter
    End With
End Sub

jeffreybrown,

this worked - thank you so much!!!

When you used my code, you activated the sheet, but did not set the WS object to the sheet, so "ws" in the code had no meaning. You simply needed

Set ws = ThisWorkbook.Worksheets("B291-Inventory Report by Locati")

at the start.

Thanks for fixing your post (#4)

If you are happy with the solution and the issue is resolved, please mark the thread as solved when you have a moment?

Thanks in advance, and happy coding

EDIT: I should also have taken a moment to say welcome to the forum! I believe you will find lots of people eager to be helpful when you have the need for it.