Fill listbox with additem

You can't use AddItem if you want 28 columns. You have to populate an array with the data and then assign that to the listbox. Which columns are you trying to add?

Or try this

PHP Code: 

Private Sub UserForm_Initialize()
    
    Dim m As Long
    Dim myrange As Range
    Dim wsh As Worksheet
    Set wsh = Worksheets("Suivi2")
    m = wsh.Range("A" & wsh.Rows.Count).End(xlUp).Row
    Me.ListBox1.RowSource = ""
    With wsh.Sort
        .SortFields.Clear
        .SortFields.Add Key:=Range("AB2:AB" & m), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
        .SortFields.Add Key:=Range("I2:I" & m), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
'
        .SetRange Range("A2:AB" & m)
        .Header = xlYes
        .MatchCase = False
        .Orientation = xlTopToBottom
        .SortMethod = xlPinYin
        .Apply
    End With
    With wsh
'        .AutoFilter
        .Range("A2:AB" & m).AutoFilter Field:=9, Criteria1:="<>NA", _
        Operator:=xlAnd
        .Range("A2:AB" & m).AutoFilter Field:=28, Criteria1:="=10", _
        Operator:=xlAnd
    End With
    Set myrange = wsh.Range("A2:AB" & Cells(Rows.Count, "A").End(xlUp).Row).SpecialCells(xlCellTypeVisible)
    Me.ListBox1.RowSource = myrange.Address
    
End Sub 


Taking the full advantage of unused Excel cells.

PHP Code: 

Private Sub UserForm_Initialize()
    
    Dim m As Long, n As Long
    Dim myrange As Range
    Dim wsh As Worksheet
    
    Set wsh = Worksheets("Suivi2")
    m = wsh.Range("A" & wsh.Rows.Count).End(xlUp).Row
    n = wsh.Range("A1").End(xlToRight).Column
    Me.ListBox1.columncount = n
    Me.ListBox1.RowSource = ""
    With wsh
        With .Sort
            .SortFields.Clear
            .SortFields.Add Key:=Range("AB2:AB" & m), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
            .SortFields.Add Key:=Range("I2:I" & m), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
'
            .SetRange wsh.Range(wsh.Cells(2, 1), wsh.Cells(m, n))
            .Header = xlYes
            .MatchCase = False
            .Orientation = xlTopToBottom
            .SortMethod = xlPinYin
            .Apply
        End With
        .Range(.Cells(1, 1), .Cells(m, n)).AutoFilter Field:=9, Criteria1:="<>NA", _
        Operator:=xlAnd
        .Range(.Cells(1, 1), .Cells(m, n)).AutoFilter Field:=28, Criteria1:="=10", _
        Operator:=xlAnd
        
        Set myrange = .Range(.Cells(2, 1), .Cells(m, n)).SpecialCells(12)
        
        myrange.Copy .Range("FX1")
        Me.ListBox1.List = .Range("FX1").CurrentRegion.Value
        .Range("FX1").CurrentRegion.Clear
    End With
End Sub 


You may expand it to more than 30 columns without resetting Listbox's Columncount.


Note: Please always test code on a copy of your file and if according to requirements then apply on the original file.

Originally Posted by dark_prince69

Can't i adapt to code just like this?
Cause as i can see on your code it's copying the cells to another worksheet right?

Copying on the same sheet away from your original data, loading into listbox and clearing the copied data.

Originally Posted by dark_prince69

also with this code it filters from the A2 so the first row appears like a header i've already changed to A1 but it's the same

The workbook that I used in my experiment started from row 2.