Advanced Loop function help

Hi experts

I hope you'll help me with my little issue here,

I don't know how to start this coding, I need to do for my sensitivity analysis ( følsomheds analyse in Danish)

The think is a want to change some variables ( 2 to be exact ) when these variables change, the model will calculate a specific number, which I needs to copy and paste in the respective cell. (if necessary see attachment )

Example : I would need to transfere 1% (b80) in b26 and 5,79% (a81) in b24,( there are current values in these cells )

then excel will calculate the need value right away, then I need to copy cell j64 and paste it to where b81 is, ( the point where A81 and B80 meets )

from here loop until Colum A is "" all the time paste a new variable to where the cells meet in the sensitivity analyse. And then jump to next row. when its all done then to reset the values in B26 and B24 as it startet.

write if im talking nonsense, hope you would help me

best regals André

I think you'll need to attached the Excel file here; it's difficult to work with an image.

WBD

Hey there,

Give this macro a try and let me know if the numbers look correct!

Public Sub FillAnalysisTable()

Dim valSheet As Worksheet
Dim b26 As Variant
Dim b24 As Variant
Dim lastRow As Long
Dim lastCol As Long
Dim thisRow As Long
Dim thisCol As Long

Set valSheet = Sheets("Valuation")
With valSheet
    b26 = .Range("B26").Value
    b24 = .Range("B24").Formula
    lastRow = .Cells(.Rows.Count, "A").End(xlUp).Row
    lastCol = .Cells(80, .Columns.Count).End(xlToLeft).Column
    For thisRow = 81 To lastRow
        .Range("B24").Value = .Cells(thisRow, "A").Value
        For thisCol = 2 To lastCol
            .Range("B26").Value = .Cells(80, thisCol).Value
            .Calculate
            .Cells(thisRow, thisCol).Value = .Range("J64").Value
        Next thisCol
    Next thisRow
    .Range("B26").Value = b26
    .Range("B24").Formula = b24
End With

End Sub

WBD