VBA Code isn't using the entire data set

Another solution, without the loop. It should be faster.

Sub Button2_Click()
    Dim lRow1       As Long
    Dim lRow2       As Long
    Dim rngData     As Range

    Application.ScreenUpdating = False
    Application.Calculation = xlCalculationManual
    
    On Error Resume Next

    With Sheet1
        .AutoFilter.ShowAllData
        lRow1 = .Cells(.Rows.Count, "B").End(xlUp).Row
        .Range("B1:B" & lRow1).AutoFilter Field:=1, Criteria1:="A380-800"

        Set rngData = .Range("B2:B" & lRow1).EntireRow.SpecialCells(xlCellTypeVisible)
    End With

    If Not rngData Is Nothing Then
        With Worksheets("A380- 800s")
            lRow2 = .Range("A" & .Rows.Count).End(xlUp).Row + 1
            rngData.Copy .Cells(lRow2, "A")
        End With

        rngData.Delete
    End If

    Sheet1.AutoFilter.Range.AutoFilter
    Application.Calculation = xlCalculationAutomatic
End Sub

Artik

Hello Idaly,

It's always a good idea to use the AutoFilter on large data sets rather than a loop construct, so you could refine the use of the Autofilter as follows:-

Option Explicit
Sub IdalyTest()

    Dim wsA As Worksheet: Set wsA = Sheets("A380-800s")
    
    Application.ScreenUpdating = False
    
        With Sheet1.Range("B1", Sheet1.Range("B" & Sheet1.Rows.Count).End(xlUp))
                .AutoFilter 1, "A380-800"
                .Offset(1).Resize(.Rows.Count - 1).Copy wsA.Range("A" & Rows.Count).End(3)(2)
                .Offset(1).EntireRow.Delete
                .AutoFilter
        End With
    
    Application.ScreenUpdating = True

End Sub

I hope that this helps.

Cheerio,
vcoolio.

Thank you everyone for the help!

You're welcome Idaly. Glad we could help.

Cheerio,
vcoolio.