Code to show when a cell was updated, for several columns

I have this code which will show when a cell has been updated in column P.

I would like it to also update for columns C, K, P & Q Too.

Is that possible?

Any help appreciated.

Private Sub Worksheet_Change(ByVal Target As Range)
'Update 20140722
Dim WorkRng As Range
Dim Rng As Range
Dim xOffsetColumn As Integer
Set WorkRng = Intersect(Application.ActiveSheet.Range("p:p"), Target)
xOffsetColumn = 15
If Not WorkRng Is Nothing Then
    Application.EnableEvents = False
    For Each Rng In WorkRng
        If Not VBA.IsEmpty(Rng.Value) Then
            Rng.Offset(0, xOffsetColumn).Value = Now
            Rng.Offset(0, xOffsetColumn).NumberFormat = "dd-mm-yyyy, hh:mm:ss"
        Else
            Rng.Offset(0, xOffsetColumn).ClearContents
        End If
    Next
    Application.EnableEvents = True
End If
End Sub

Possibly...

Private Sub Worksheet_Change(ByVal Target As Range)

    Select Case Target.Column
        Case Is = 3, 11, 16, 17
            Application.EnableEvents = False
            With Cells(Target.Row, 30)
                .Value = Now
                .NumberFormat = "dd-mm-yyyy, hh:mm:ss"
            End With
            Application.EnableEvents = True
    End Select

    
End Sub

Thank you I will try those

One more variant

Private Sub Worksheet_Change(ByVal Target As Range)
 With Application
   If IsNumeric(.Match(Target.Column, Array(3, 11, 16, 17), 0)) Then
     .EnableEvents = False
      Cells(Target.Row, 30).Value = Format(Now, "dd-mm-yyyy, hh:mm:ss")
     .EnableEvents = True
   End If
 End With
End Sub

Thanks all for the help, they do work.

However I want the chnages to show as independant.

So at the moment if I change column c or p for example the time and date updates in the column.

What I want it to do is show a column update for each individual column, so if c or p change on a different date i can track it.

Does that make sense?

Possibly...

Private Sub Worksheet_Change(ByVal Target As Range)

    Select Case Target.Column
        Case Is = 3, 11, 16, 17
            Application.EnableEvents = False
            With Cells(Target.Row, 30 + Target.Column)
                .Value = Now
                .NumberFormat = "dd-mm-yyyy, hh:mm:ss"
            End With
            Application.EnableEvents = True
    End Select
    
End Sub

Thank you.

That is perfect and adaptable now

Glad I could help!