Troubleshooting VBA Code Error and Clarifying Steps for Data Filtering and Formulas

Hi, how's your VBA knowledge in general?
As you have stated the code you're using is CHTGPT generated but can I assume that you made some modifications to it to suit your purposes?

Hi. It looks like there is no knowledge at all in VBA, just copy - paste. Try the modified code:

Option Explicit

Sub SMBCFUNDS_by_MikeVol()
    Dim wbPath  As String: wbPath = "R:\Shipping Group\- SMBC INCOMING FUND REPORTS.xlsm"
    Application.ScreenUpdating = False

    With ActiveSheet
        .AutoFilterMode = False
        .Range(.Cells(4, 26), .Cells(4, 33)).AutoFilter

        With .Range("$Z$4:$AG$" & .Cells(.Rows.Count, "Z").End(xlUp).Row)
            .AutoFilter Field:=5, Criteria1:="="
            .AutoFilter Field:=1, Criteria1:="SMBC"
        End With

        Dim visibleRows As Long: visibleRows = .Range("$Z$5:$Z$" & .Cells(.Rows.Count, "Z").End(xlUp).Row).SpecialCells(xlCellTypeVisible).Count
        Dim lastRow As Long: lastRow = .Cells(.Rows.Count, "Z").End(xlUp).Row

        If visibleRows <= 1 Then
            .ShowAllData
            MsgBox "No rows found matching the criteria. Process stopped."
            Application.ScreenUpdating = True
            Exit Sub
        End If

        If FileExists(wbPath) Then
            Dim wbFile As Workbook: Set wbFile = Workbooks.Open(wbPath, ReadOnly:=True)
            Dim ws  As Worksheet: Set ws = wbFile.Worksheets("USD&JPY")
            Dim wbName As String: wbName = wbFile.Name

            With .Range("AD5:AE" & lastRow).SpecialCells(xlCellTypeVisible)

                ' Insert formulas
                .FormulaR1C1 = "=IFERROR(INDEX('" & "[" & wbName & "]" & Replace(ws.Name, "'", "''") & "'!C11, MATCH(RC[-22],'" & "[" & wbName & "]" & Replace(ws.Name, "'", "''") & "'!C16, 0)), """")"
                .Offset(, 1).FormulaR1C1 = "=IFERROR(INDEX('" & "[" & wbName & "]" & Replace(ws.Name, "'", "''") & "'!C13, MATCH(RC[-23],'" & "[" & wbName & "]" & Replace(ws.Name, "'", "''") & "'!C16, 0)), """")"
                Application.Calculation = xlCalculationManual

                ' Convert formulas to values
                .Value = .Value
                .Offset(, 1).Value = .Offset(, 1).Value
            End With

            wbFile.Close SaveChanges:=False
        End If

        .AutoFilter.ShowAllData
    End With

    Set wbFile = Nothing
    Set ws = Nothing

    Application.Calculation = xlCalculationAutomatic
    Application.ScreenUpdating = True

    MsgBox "Payment Updated!"
End Sub

Function FileExists(ByVal FilePath As String) As Boolean
    On Error Resume Next
    FileExists = (Dir(FilePath) <> "")
    On Error GoTo 0
End Function

Good luck.

Administrative Note:

Is your forum profile showing the oldest Excel PRODUCT that you need this to work for?

Members will tailor the solutions they offer to the Office PRODUCT (Excel, NOT Windows) that you have. Please check that your forum profile is up-to-date in this respect. If you aren't sure, in Excel go to File | Account and report what it says below the MS logo at the top of that page. If your product is for Mac, please also state this.

The three most recent Excel products are Excel 2019, Excel 2021 and MS365 - if you are using MS365, please give this name along with the version number in your profile (e.g. MS365 Version 2306). This is in the About Excel section further down the Account page.

Thanks.

Please respond to post #5.

OK - it's important.

The code will not copy anything! What is the search criterion in the formulas? That's right, in column H. What do you have in the cells of column H? That's right, a drop-down list. Is there a value in these drop-down lists that should correspond to column P? That's right, there are no such values. Read about the INDEX and MATCH functions then you can change the formulas to suit your needs. If you substitute the required values ​​in the cells in the H column, then everything is fine and copies correctly. See screenshots. Good luck.
P.S.Don't pay attention to the file path in the screenshot, I was setting up the code.