Keeping track of used vacation hours

I had a Yahoo toolbar that was blocking popups. What an ordeal.

I have a spreadsheet that I use for keeping track of my vacation hours used at work. I am trying to get it to work automatically. I have been trying by using a vlookup, but I can't get the data to list the way I need it. I have attached a .zip file with an abbreviated portion of what I am trying to do. Maybe someone here could get this thing to work.

Thank you

Hello Fast Forward,

These macros have been added to the attached workbook.

Standard Module

Sub CompileVacationHours()

  Dim LastRow As Long
  Dim N As Long, R As Long
  
    LastRow = Cells(Rows.Count, "B").End(xlUp).Row
      If LastRow < 6 Then LastRow = 6
    N = 6
    
    Range(Cells(6, "I"), Cells(LastRow, "L")).ClearContents
    
      For R = 6 To LastRow
        If Cells(R, "D") <> "" Then
           Range(Cells(N, "I"), Cells(N, "L")).Value = Range(Cells(R, "B"), Cells(R, "E")).Value
           N = N + 1
        End If
      Next R
           
End Sub

Worksheet Sheet1 Change Event

Private Sub Worksheet_Change(ByVal Target As Range)

  Dim EntryRng As Range
  Dim LastRow As Long
  
    Application.EnableEvents = False
    
      LastRow = Cells(Rows.Count, "B").End(xlUp).Row
      Set EntryRng = Range(Cells(6, "B"), Cells(LastRow, "E"))
    
        If Not Intersect(Target, EntryRng) Is Nothing Then
           Call CompileVacationHours
        End If
        
    Application.EnableEvents = True
    
End Sub

Sincerely,
Leith Ross